Class HauptForm
 
  Dim startCorner As Point
  Dim rubberBand As Rectangle
  Dim rubberBanding As Boolean = False
  Dim rubberBandColor As Color = Color.Yellow
 
  Private Sub HauptForm_Load(sender As Object, e As EventArgs) Handles _
    MyBase.Load
    Me.PictureBox1.SizeMode = PictureBoxSizeMode.Normal
    Me.PictureBox4.SizeMode = PictureBoxSizeMode.Zoom
  End Sub
 
  Private Sub PictureBox1_MouseDown(sender As Object, e As MouseEventArgs) _
    Handles PictureBox1.MouseDown
    If e.Button = MouseButtons.Left Then
      rubberBanding = True
      startCorner = e.Location
      rubberBand = Rectangle.Empty
      PictureBox1.Invalidate()
    End If
  End Sub
 
  Private Sub PictureBox1_MouseMove(sender As Object, e As MouseEventArgs) _
    Handles PictureBox1.MouseMove
    If rubberBanding Then
      rubberBand.Width = Math.Abs(e.X - startCorner.X)
      rubberBand.Height = Math.Abs(e.Y - startCorner.Y)
      rubberBand.X = Math.Min(e.X, startCorner.X)
      rubberBand.Y = Math.Min(e.Y, startCorner.Y)
      PictureBox1.Invalidate()
    End If
  End Sub
 
  Private Sub PictureBox1_MouseUp(sender As Object, e As MouseEventArgs) _
    Handles PictureBox1.MouseUp
    rubberBanding = False
    Dim bm As New Bitmap(PictureBox1.Image)
    PictureBox4.Image = bm.Clone(rubberBand, Imaging.PixelFormat.DontCare)
  End Sub
 
  Private Sub PictureBox1_Paint(sender As Object, e As PaintEventArgs) Handles _
    PictureBox1.Paint
    Using pn As New Pen(rubberBandColor, 2) With {.DashStyle = _
    Drawing2D.DashStyle.Dash}
      e.Graphics.DrawRectangle(pn, rubberBand)
    End Using
  End Sub
 
End Class