Private _mouseDown As Boolean = False
    Private _draggedPoint As DataPoint
 
 
 
    Private Sub ChartEngine_MouseDown(sender As Object, e As _
      System.Windows.Forms.MouseEventArgs) Handles ChartEngine.MouseDown
        Dim result As HitTestResult = ChartEngine.HitTest(e.X, e.Y)
 
        If result.ChartElementType = ChartElementType.DataPoint Then
            _draggedPoint = ChartEngine.Series(0).Points(result.PointIndex)
            _mouseDown = True
        End If
    End Sub
 
    Private Sub ChartEngine_MouseMove(sender As Object, e As _
      System.Windows.Forms.MouseEventArgs) Handles ChartEngine.MouseMove
        If _mouseDown Then
 
            Dim area As ChartArea = ChartEngine.ChartAreas(0)
 
            'Mouse coordinates should not be outside of the chart 
            Dim yValue As Double = area.AxisY.PixelPositionToValue(Math.Max( _
              Math.Min(e.Y, ChartEngine.Size.Height - 1), 0))
            yValue = Math.Min(yValue, area.AxisY.Maximum)
            yValue = Math.Max(yValue, area.AxisY.Minimum)
 
            Dim xValue As Double = area.AxisX.PixelPositionToValue(Math.Max( _
              Math.Min(e.X, ChartEngine.Size.Width - 1), 0))
            xValue = Math.Min(xValue, area.AxisX.Maximum)
            xValue = Math.Max(xValue, area.AxisX.Minimum)
 
            _draggedPoint.XValue = xValue
            _draggedPoint.YValues(0) = yValue
 
            ChartEngine.Invalidate()
        Else
            'Set different shape of cursor over the data points
            Dim result As HitTestResult = ChartEngine.HitTest(e.X, e.Y)
 
            If result.ChartElementType = ChartElementType.DataPoint Then
                ChartEngine.Cursor = Cursors.Hand
            Else
                ChartEngine.Cursor = Cursors.Default
            End If
        End If
    End Sub
 
    Private Sub ChartEngine_MouseUp(sender As Object, e As _
      System.Windows.Forms.MouseEventArgs) Handles ChartEngine.MouseUp
        _mouseDown = False
    End Sub