Imports System.ComponentModel
 
Public Class CheckPic
    Inherits PictureBox
 
    Dim _checkdefault, _uncheckdefault As Bitmap
    Dim _checkpic, _uncheckpic As Bitmap
    Dim _checked As Boolean
 
    Public Sub New()
 
        Me.SizeMode = PictureBoxSizeMode.Zoom
 
        _checkdefault = New Bitmap(300, 30)
        Using g As Graphics = Graphics.FromImage(_checkdefault),
            br As New SolidBrush(Color.Blue)
            g.Clear(Color.White)
            g.DrawString("Checked", New Font("Arial", 10, _
               FontStyle.Bold), br, 2, 2)
        End Using
 
        _uncheckdefault = New Bitmap(300, 30)
        Using g As Graphics = Graphics.FromImage(_uncheckdefault),
            br As New SolidBrush(Color.Black)
            g.Clear(Color.White)
            g.DrawString("Unchecked", New Font("Arial", 10), br, 2, 2)
        End Using
 
        Me.Width = 300 : Me.Height = 30
        Me.Image = _uncheckdefault
    End Sub
 
    Private Sub SetPic()
        If _checked Then
            If Not _checkpic Is Nothing Then
                Me.Image = _checkpic
            Else
                Me.Image = _checkdefault
            End If
        Else
            If Not _uncheckpic Is Nothing Then
                Me.Image = _uncheckpic
            Else
                Me.Image = _uncheckdefault
            End If
        End If
    End Sub
 
    Public Property Checked() As Boolean
        Set(value As Boolean)
            _checked = value
            SetPic()
        End Set
        Get
            Return _checked
        End Get
    End Property
 
    <Browsable(True)> _
       Public Property CheckPic() As Image
        Set(value As Image)
            If Not value Is Nothing Then
                _checkpic = New Bitmap(value)
                SetPic()
            End If
        End Set
        Get
            Return _checkpic
        End Get
    End Property
 
    <Browsable(True)> _
    Public Property UnCheckPic() As Image
        Set(value As Image)
            If Not value Is Nothing Then
                _uncheckpic = New Bitmap(value)
                SetPic()
            End If
        End Set
        Get
            Return _uncheckpic
        End Get
    End Property
 
    Private Sub CheckPic_Click(sender As Object, _
        e As System.EventArgs) Handles Me.Click
        _checked = Not _checked
        SetPic()
    End Sub
End Class