Imports System.ComponentModel
 
Public Class FindFiles
 
    Dim WithEvents bg As New BackgroundWorker _
        With {.WorkerReportsProgress = True, _
              .WorkerSupportsCancellation = True}
 
    Public Property FilePattern As String = ""
 
    Public Property BaseDirectory As String = ""
 
    Private _FileList As New List(Of String)
 
 
    Public Class FindFilesEventArgs
        Inherits System.EventArgs
 
        Dim _ra As ReportArgs
        Public Sub New(report As ReportArgs)
            _ra = report
        End Sub
 
        Public Function FilesFound() As Integer
            Return _ra.FilesFound
        End Function
    End Class
 
 
    Public Event Finished(ByVal sender As Object, ByVal e As FindFilesEventArgs)
    Public Event Progress(ByVal sender As Object, ByVal e As FindFilesEventArgs)
    Public Event Aborted(ByVal sender As Object, ByVal e As EventArgs)
 
 
    Public Structure ReportArgs
        Friend FilesFound As Integer
        Friend abort As Boolean
    End Structure
 
    Dim _reportargs As New ReportArgs
 
 
    Public Function Find() As Boolean
 
        If Not IO.Directory.Exists(BaseDirectory) Then Return False
 
        _FileList.Clear()
        _reportargs.FilesFound = 0
        _reportargs.abort = False
 
        bg.RunWorkerAsync()
        Return True
    End Function
 
 
    Private Sub bg_DoWork(sender As Object, _
        e As System.ComponentModel.DoWorkEventArgs) Handles bg.DoWork
 
        FindFiles(BaseDirectory)
    End Sub
 
 
    Private Sub FindFiles(ByVal folder As String)
        Try
            If bg.CancellationPending Then Exit Sub
 
            For Each file As String In _
                IO.Directory.EnumerateFiles(folder, FilePattern)
                With _reportargs
                    .FilesFound += 1
                    _FileList.Add(file)
                    bg.ReportProgress(0, _reportargs)
                End With
            Next file
 
            For Each fld As String In IO.Directory.GetDirectories(folder)
                FindFiles(fld)
            Next fld
        Catch ex As UnauthorizedAccessException
        End Try
 
    End Sub
 
 
    Public Sub Abort()
        _reportargs.abort = True
        If bg.IsBusy Then bg.CancelAsync()
    End Sub
 
 
    Private Sub bg_ProgressChanged(sender As Object, _
            e As System.ComponentModel.ProgressChangedEventArgs) Handles _
            bg.ProgressChanged
        RaiseEvent Progress(Me, New FindFilesEventArgs(_reportargs))
    End Sub
 
 
    Private Sub bg_RunWorkerCompleted(sender As Object, _
        e As System.ComponentModel.RunWorkerCompletedEventArgs) Handles _
        bg.RunWorkerCompleted
        If _reportargs.abort Then
            RaiseEvent Aborted(Me, EventArgs.Empty)
        Else
            RaiseEvent Finished(Me, New FindFilesEventArgs(_reportargs))
        End If
    End Sub
 
 
    Public ReadOnly Property FilesFound As List(Of String)
        Get
            Return _FileList
        End Get
    End Property
End Class