Public Sub CreateDemoFormProjekt(ByVal displaytext As String)
 
   Dim nl As String = Microsoft.VisualBasic.vbCrLf
   Dim c34 As String = Microsoft.VisualBasic.Chr(34)
 
   Using VB_CP As CodeDom.Compiler.CodeDomProvider = _
      New Microsoft.VisualBasic.VBCodeProvider()
 
      'Angaben für das Compilieren des Win-Forms-Projekts zusammenstellen
      Dim ComParams As New CodeDom.Compiler.CompilerParameters()
 
      With ComParams
         .GenerateExecutable = True
         'benötigte Projekt-Verweise
         .ReferencedAssemblies.Add("System.Windows.Forms.DLL")
         .ReferencedAssemblies.Add("System.Drawing.DLL")
         'Erstellte Datei
         .OutputAssembly = "C:\Daten\DemoFormProjekt.Exe"
 
         .GenerateInMemory = False
         .CompilerOptions = "/target:winexe"
         .MainClass = "xxxform"
     End With
 
     'Code-String zum Erstellen eines Projekts, das eine Form öffnet
     '(Man könnte den Code auch aus einer VB-Datei laden ... incl. Designer)
     Dim code As String = _
     "Imports System.Windows.Forms" & nl & _
     "Imports System.Drawing" & nl & _
     "Public Class xxxform" & nl & _
         "Inherits System.Windows.Forms.Form" & nl & _
         "Dim lblInfo As New Label With _ " & nl & _
         "{.Parent = Me, .Width = 300, .Height = 300} " & nl & _
         "Private Sub xxxform_Load(sender As System.Object, " & _
              "e As System.EventArgs) Handles MyBase.Load" & nl & _
             "Me.Size = New Size(350, 350)" & nl & _
             "lblInfo.text = " & c34 & displaytext & c34 & nl & _
         "End Sub" & nl & _
         "Private Sub InitializeComponent()" & nl & _
             "Me.SuspendLayout() " & nl & _
             "Me.ClientSize = New System.Drawing.Size(292, 273) " & nl & _
             "Me.Name = " & c34 & "xxxform" & c34 & nl & _
             "Me.ResumeLayout(False) " & nl & _
         "End Sub" & nl & _
      "End Class"
 
      'Code-Zeichenfolge Compilieren und EXE erstellen 
      Dim ComResults As CodeDom.Compiler.CompilerResults = _
         VB_CP.CompileAssemblyFromSource(ComParams, code)
 
      'ggf. Compiler-Fehlermeldungen anzeigen 
      Dim et As String = ""
      With ComResults
         If .Errors.Count > 0 Then
            et = "Fehler: " & nl
            For i As Integer = 0 To .Errors.Count - 1
               et &= .Errors(i).ErrorText & " (" & .Errors(i).Line.ToString & _
                 ")" & nl
            Next i
        Else
            et = "DemoFormProjekt ist erstellt worden"
        End If
     End With
 
     MessageBox.Show(et)
   End Using
End Sub