Public Class frmCellPaintingDemo
 
    Dim WithEvents dgv As New DataGridView With {.Parent = Me}
    Dim dt As New DataTable
 
    Dim IconA As New Icon("....ico") 'Iconfile ageben
    Dim iconG As New Icon("....ico")
 
 
 
    Private Sub frmCellPaintingDemo_Load(sender As System.Object, _
                                    e As System.EventArgs) Handles MyBase.Load
 
        'Testdaten 
        dt.Columns.Add("status")
        dt.Columns.Add("ID", GetType(Integer))
        dt.Rows.Add("A", 1) : dt.Rows.Add("G", 2) : dt.Rows.Add("A", 3)
 
        dgv.DataSource = dt
 
        dgv.Columns("status").MinimumWidth = 50
 
        For i As Integer = 0 To dgv.Rows.Count - 1
            dgv.Rows(i).MinimumHeight = IconA.Height
        Next i
    End Sub
 
 
    Private Sub dgv_CellPainting(sender As Object, _
        e As System.Windows.Forms.DataGridViewCellPaintingEventArgs) _
        Handles dgv.CellPainting
 
        If e.RowIndex < 0 Or e.ColumnIndex < 0 Then Exit Sub
 
        If dgv.Columns(e.ColumnIndex).Name = "status" Then
            'Ist die Zelle selektiert ? 
            Dim selected As Boolean = _
            (e.State And DataGridViewElementStates.Selected) = _
            DataGridViewElementStates.Selected
 
            e.PaintBackground(e.CellBounds, selected)
 
            Dim ico As Icon
            If Not e.Value Is Nothing Then
                'Textfarbe einrichten
                Dim col As Color
                If selected Then col = Color.White Else col = Color.Black
 
                Using br As New SolidBrush(col)
                    'Text ausgeben A/G
                    e.Graphics.DrawString _
                        (e.Value.ToString & " |", dgv.Font, br, _
                         e.CellBounds.X + 2, e.CellBounds.Y)
 
                    'Passendes Icon zeichnen 
                    If e.Value.ToString = "A" Then ico = IconA Else ico = iconG
                    e.Graphics.DrawIcon _
                        (ico, New Rectangle(e.CellBounds.X + 20, _
                         e.CellBounds.Y, ico.Width, ico.Height))
                End Using
            End If
 
            e.Handled = True 'Diese Zelle ist gezeichnet 
        End If
    End Sub
End Class