Function MischMich(Farbe1 As Color, Farbe2 As Color, Optional AnteilFarbe1 _
      As Double = 0.5) As Color
        Dim AnteilFarbe2 As Double = 1 - AnteilFarbe1
        '▼▼▼ Trennen in RGB-Variablen für einfachere 
        ' Handhabung beim Experimentieren,
        ' etwas übertrieben nach Double, wird alles später optimiert ;-)
        Dim R1 As Double = Farbe1.R
        Dim G1 As Double = Farbe1.G
        Dim B1 As Double = Farbe1.B
        Dim R2 As Double = Farbe2.R
        Dim G2 As Double = Farbe2.G
        Dim B2 As Double = Farbe2.B
        '▼▼▼ Umrechnen von RGB --> CMY:
        ' Vielleicht schon da ein Fehler?
        ' Ist das überhaupt nötig? 
        ' Vielleicht geht die Addition auch direkt aus RGB?
        Dim C1 As Double = 255 - R1
        Dim M1 As Double = 255 - G1
        Dim Y1 As Double = 255 - B1
        Dim C2 As Double = 255 - R2
        Dim M2 As Double = 255 - G2
        Dim Y2 As Double = 255 - B2
        '▼▼▼ Addition:
        ' Klappt bei dunklen Farben einigermaßen. Helle werden aber ZU hell.
        Dim C3 As Double = C1 * AnteilFarbe1 + C2 * AnteilFarbe2
        Dim M3 As Double = M1 * AnteilFarbe1 + M2 * AnteilFarbe2
        Dim Y3 As Double = Y1 * AnteilFarbe1 + Y2 * AnteilFarbe2
        '▼▼▼ Zurück nach RGB:
        Dim R3 As Double = 255 - C3
        Dim G3 As Double = 255 - M3
        Dim B3 As Double = 255 - Y3
        '▼▼▼ Und zurück als Farbe:
        Return Color.FromArgb(R3, G3, B3)
    End Function

    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) _
      Handles MyBase.Load
        ' Mache ich sonst im Designer, für's Forum mal so:
        TrackBar1.Maximum = 100
        TrackBar1.TickFrequency = 10
        TrackBar1.RightToLeft = Windows.Forms.RightToLeft.Yes
        TrackBar1.Value = 50
        Panel1.BackColor = Color.FromArgb(0, 255, 255)
        Panel2.BackColor = Color.FromArgb(255, 255, 0)
        Label1.Text = TrackBar1.Value & "% : " & 100 - TrackBar1.Value & "%"
    End Sub
    Private Sub Panels_Click(sender As Object, e As System.EventArgs) Handles _
      Panel1.Click, Panel2.Click
        ColorDialog1.Color = DirectCast(sender, Panel).BackColor
        If ColorDialog1.ShowDialog = Windows.Forms.DialogResult.OK Then
            DirectCast(sender, Panel).BackColor = ColorDialog1.Color
        End If
    End Sub
    Private Sub Panels_BackColorChanged(sender As Object, e As _
      System.EventArgs) Handles Panel1.BackColorChanged, Panel2.BackColorChanged
        Panel3.BackColor = MischMich(Panel1.BackColor, Panel2.BackColor, _
        TrackBar1.Value / 100)
    End Sub
    Private Sub TrackBar1_Scroll(sender As System.Object, e As _
      System.EventArgs) Handles TrackBar1.Scroll
        Panel3.BackColor = MischMich(Panel1.BackColor, Panel2.BackColor, _
        TrackBar1.Value / 100)
        Label1.Text = TrackBar1.Value & "% : " & 100 - TrackBar1.Value & "%"
    End Sub

--
while (!asleep()) sheep++;

    ''' <summary>Umrechnung von RGB in CMYK Farbraum</summary>
    ''' <param name="red">In: Red</param>
    ''' <param name="green">In: Green</param>
    ''' <param name="blue">In: Blue</param>
    ''' <param name="cyan">Out: Cyan</param>
    ''' <param name="magenta">Out: Magenta</param>
    ''' <param name="yellow">Out Yellow</param>
    ''' <param name="key">Out: Key</param>
    Public Sub RGB2CMYK(ByVal red As Byte, green As Byte, blue As Byte, _
              ByRef cyan As Double, ByRef magenta As Double, _
              ByRef yellow As Double, ByRef key As Double)
 
        'http://www.easyrgb.com/index.php?X=MATH&H=13#text13
 
 
        cyan = 1 - (red / 255)
        magenta = 1 - (green / 255)
        yellow = 1 - (blue / 255)
 
        key = 1.0
        If cyan < key Then key = cyan
        If magenta < key Then key = magenta
        If yellow < key Then key = yellow
 
        If (key = 1.0) Then
            cyan = 0.0
            magenta = 0.0
            yellow = 0.0
        Else
            cyan = (cyan - key) / (1.0 - key)
            magenta = (magenta - key) / (1.0 - key)
            yellow = (yellow - key) / (1 - key)
        End If
    End Sub
 
 
    ''' <summary>Umrechnung von CMYK in RGB Farbraum</summary>
    ''' <param name="red">Out: Red</param>
    ''' <param name="green">Out: Green</param>
    ''' <param name="blue">Out: Blue</param>
    ''' <param name="cyan">In: Cyan</param>
    ''' <param name="magenta">In: Magenta</param>
    ''' <param name="yellow">In: Yellow</param>
    ''' <param name="key">In: Key</param>
    Public Sub CMYK2RGB(ByVal cyan As Double, ByVal magenta As Double, _
                         ByVal yellow As Double, ByVal key As Double,
                         ByRef red As Byte, ByRef green As Byte, ByRef blue As _
                           Byte)
 
        cyan = (cyan * (1.0 - key) + key)
        magenta = (magenta * (1 - key) + key)
        yellow = (yellow * (1.0 - key) + key)
 
        red = CByte((1.0 - cyan) * 255)
        green = CByte((1.0 - magenta) * 255)
        blue = CByte((1.0 - yellow) * 255)
 
    End Sub

--
while (!asleep()) sheep++;

--
while (!asleep()) sheep++;

--
while (!asleep()) sheep++;

Public Class frmCMYK
 
    Dim WithEvents cyan As New TrackBar With _
        {.Parent = Me, .Minimum = 0, .Maximum = 100, _
         .Top = 10, .Height = 20, .Width = 300, .TickStyle = TickStyle.None}
 
    Dim WithEvents magenta As New TrackBar With _
        {.Parent = Me, .Minimum = 0, .Maximum = 100, _
         .Top = cyan.Top + 40, .Height = 20, .Width = 300, .TickStyle = _
         TickStyle.None}
 
    Dim WithEvents yellow As New TrackBar With _
        {.Parent = Me, .Minimum = 0, .Maximum = 100, _
         .Top = magenta.Top + 40, .Height = 20, .Width = 300, .TickStyle = _
         TickStyle.None}
 
    Dim WithEvents key As New TrackBar With _
        {.Parent = Me, .Minimum = 0, .Maximum = 100, _
         .Top = yellow.Top + 40, .Height = 20, .Width = 300, .TickStyle = _
         TickStyle.None}
 
    Dim WithEvents pb As New PictureBox _
        With {.Parent = Me, .Top = key.Top + 40, .Width = 300, .Height = 200}
 
 
    Dim WithEvents cyan2 As New TrackBar With _
        {.Parent = Me, .Minimum = 0, .Maximum = 100, _
         .Top = 10, .Height = 20, .Width = 300, .TickStyle = TickStyle.None, _
         .Left = 320}
 
    Dim WithEvents magenta2 As New TrackBar With _
        {.Parent = Me, .Minimum = 0, .Maximum = 100, _
         .Top = cyan.Top + 40, .Height = 20, .Width = 300, .TickStyle = _
         TickStyle.None, _
         .Left = 320}
 
    Dim WithEvents yellow2 As New TrackBar With _
        {.Parent = Me, .Minimum = 0, .Maximum = 100, _
         .Top = magenta.Top + 40, .Height = 20, .Width = 300, .TickStyle = _
         TickStyle.None, _
         .Left = 320}
 
    Dim WithEvents key2 As New TrackBar With _
        {.Parent = Me, .Minimum = 0, .Maximum = 100, _
         .Top = yellow.Top + 40, .Height = 20, .Width = 300, .TickStyle = _
         TickStyle.None, _
         .Left = 320}
 
    Dim WithEvents pb2 As New PictureBox _
        With {.Parent = Me, .Top = key.Top + 40, .Width = 300, .Height = 200, _
              .Left = 320}
 
    Dim lblMix As New Label With _
        {.Parent = Me, .Top = pb.top + pb.height + 10, .Width = 120, _
         .Text = "Mixfaktor Farbe1 (%):"}
 
    Dim WithEvents txtMix As New TextBox With _
        {.Parent = Me, .Top = pb.top + pb.height + 10, .Width = 100, .Left = _
        130}
    Dim WithEvents pbMix As New PictureBox With _
        {.Parent = Me, .Top = txtMix.top + txtMix.height + 10, _
         .Width = 600, .Height = 200}
 
 
    Private Sub frmCMYK_Load(sender As System.Object, _
        e As System.EventArgs) Handles MyBase.Load
        Me.Width = 660
        Me.Height = 700
    End Sub
 
    Private Sub cyan_ValueChanged(sender As Object, e As System.EventArgs) _
        Handles cyan.ValueChanged, magenta.ValueChanged, _             
                yellow.ValueChanged, key.ValueChanged, _
                cyan2.ValueChanged, magenta2.ValueChanged, _
                yellow2.ValueChanged, key2.ValueChanged
        pb.Invalidate()
        pb2.Invalidate()
        pbmix.invalidate()
    End Sub
 
    Private Sub pb_Paint(sender As Object, _
        e As System.Windows.Forms.PaintEventArgs) Handles pb.Paint, pb2.Paint
 
        Dim pb As PictureBox = DirectCast(sender, PictureBox)
 
        Dim r, g, b As Byte
 
        If pb.Left = 0 Then
            CMYK2RGB(cyan.Value / 100, magenta.Value / 100, _
                         yellow.Value / 100, key.Value / 100, _
                        r, g, b)
            e.Graphics.Clear(Color.FromArgb(r, g, b))
 
        Else
 
            CMYK2RGB(cyan2.Value / 100, magenta2.Value / 100, _
             yellow2.Value / 100, key2.Value / 100, _
            r, g, b)
            e.Graphics.Clear(Color.FromArgb(r, g, b))
 
        End If
 
    End Sub
 
 
    Private Sub pbMix_Paint(sender As Object, _
        e As System.Windows.Forms.PaintEventArgs) Handles pbMix.Paint
 
        Dim mix As Double
        If Not Double.TryParse(txtMix.Text, mix) OrElse (mix < 0 Or mix > _
          100) Then
            e.Graphics.Clear(Me.BackColor)
        Else
            Dim r, g, b As Byte
 
            Dim c As Double = _
            (mix * cyan.Value) / 10000 + (1 - mix / 100) * cyan2.Value / 100
            Dim m As Double = _
            (mix * magenta.Value) / 10000 + (1 - mix / 100) * magenta2.Value / _
            100
            Dim y As Double = _
            (mix * yellow.Value) / 10000 + (1 - mix / 100) * yellow2.Value / 100
            Dim k As Double = _
            (mix * key.Value) / 10000 + (1 - mix / 100) * key2.Value / 100
 
            CMYK2RGB(c, m, y, k, r, g, b)
 
            e.Graphics.Clear(Color.FromArgb(r, g, b))
        End If
    End Sub
 
 
    Private Sub txtMix_KeyDown(sender As Object, _
        e As System.Windows.Forms.KeyEventArgs) Handles txtMix.KeyDown
 
        If e.KeyCode = Keys.Return Then pbMix.Invalidate()
    End Sub
End Class

--
while (!asleep()) sheep++;

--
while (!asleep()) sheep++;

--
while (!asleep()) sheep++;

          C   M   Y      R   G   B
          -----------    -----------
Cyan      255 0   0      0   255 255
Magenta   0   255 0      255 0   255
Yellow    0   0   255    255 255 0
 
Rot       0   255 255    255 0   0
Grün      255 0   255    0   255 0
Blau      255 255 0      0   0   255
 
Weiß      0   0   0      255 255 255
Scharz    255 255 255    0   0   0

--
while (!asleep()) sheep++;

--
while (!asleep()) sheep++;

     Menge1 * R1 + Menge2 * R2 + Menge3 * R3 + ... + MengeX * RX
R = -------------------------------------------------------------
               Menge1 + Menge2 + Menge3 + ... + MengeX
 
G = entsprechend
 
B = entsprechend

     Menge1 * C1 + Menge2 * C2 + Menge3 * C3 + ... + MengeX * CX
C = -------------------------------------------------------------
               Menge1 + Menge2 + Menge3 + ... + MengeX
 
M = entsprechend
 
Y = entsprechend

--
while (!asleep()) sheep++;

--
while (!asleep()) sheep++;

Zitat:

3 Liter Gelb + 3 Liter Zyan ergeben 6 Liter Grün (0,255,0) Jetzt noch 3 Liter Magenta dazu und man bekommt 9 Liter Schwarz (0,0,0)

--
while (!asleep()) sheep++;