Public Class frmMultiSearch
 
    Dim WithEvents mtbo As New MaskedTextBox With _
        {.Parent = Me, .Width = 80}
 
    Dim dt As New DataTable
 
    Dim bs As New BindingSource
    Dim WithEvents dgv As New DataGridView With _
        {.Parent = Me, .Size = New Size(400, 400), .Top = 50, _
         .DataSource = bs, _
         .AllowUserToAddRows = False}
 
    Dim search_columnindex As Integer = 1 'Die kritische Spalte
 
    Dim searchlist As New List(Of String) 'Liste der Suchbegriffe
 
 
    Private Sub frmMultiSearch_Load(sender As System.Object, _
                    e As System.EventArgs) Handles MyBase.Load
 
        Me.Size = New Size(450, 500)
 
        mtbo.TextMaskFormat = MaskFormat.ExcludePromptAndLiterals
        mtbo.Mask = ">LLLL0LL"  'Eingabemaske für Suchstring
 
        'Die oben gegebenen Daten irgendwie in die Datatable ..... 
        For i As Integer = 0 To 4
            dt.Columns.Add("SP_" & CStr(i))
        Next i
 
        Dim lines() As String = IO.File.ReadAllLines("C:\daten\ex_xls.txt")
        For Each line As String In lines
            Dim fields() As String = line.Split(" "c)
            Dim k As Integer = -1
            Dim row As DataRow = dt.NewRow
            For Each field As String In fields
                If Not field.Trim = "" AndAlso k < 4 Then
                    k += 1
                    row(k) = field
                End If
            Next
            dt.Rows.Add(row)
        Next
 
        bs.DataSource = dt
    End Sub
 
 
    Private Sub mtbo_KeyDown(sender As Object, _
                e As System.Windows.Forms.KeyEventArgs) Handles mtbo.KeyDown
 
        If e.KeyCode = Keys.Return Then
            If Not mtbo.MaskFull Then
                Dim ret As MsgBoxResult = _
                    MsgBox("Keine vollständige Such-Eingabe", _
                    MsgBoxStyle.OkCancel)
                If ret = MsgBoxResult.Cancel Then Exit Sub
            End If
 
            'Anzahl der gefundenen Zeilen (incl. bereits markierte)
            Dim row_found As Integer = _
                   Aggregate row As DataRow In dt.AsEnumerable _
                      Where row(search_columnindex).ToString.StartsWith( _
                      mtbo.Text) _
                   Into Count()
 
            MsgBox(row_found.ToString & " Zeilen gefunden")
 
            If row_found > 0 AndAlso Not searchlist.Contains(mtbo.Text) Then
               searchlist.Add(mtbo.Text)
               dgv.InvalidateColumn(search_columnindex)
            End If            
        End If
    End Sub
 
 
    Private Sub dgv_CellPainting(sender As Object, _
                  e As System.Windows.Forms.DataGridViewCellPaintingEventArgs) _
            Handles dgv.CellPainting
 
        If e.RowIndex = -1 Or e.ColumnIndex = -1 Then Exit Sub
 
        Dim vl As String = _
            dgv.Rows(e.RowIndex).Cells(e.ColumnIndex).Value.ToString
 
        'Entspricht der Zellwert einem Suchbegriff (Startswith)
        Dim searched As Boolean
        For i As Integer = 0 To searchlist.Count - 1
            searched = vl.StartsWith(searchlist(i))
            If searched Then Exit For
        Next i
 
        If searched Then
            'Zelle gelb markieren
            Using bry As New SolidBrush(Color.Yellow)
                e.Graphics.FillRectangle(bry, e.CellBounds)
            End Using
            e.Paint(e.CellBounds, DataGridViewPaintParts.Border)
            e.Paint(e.CellBounds, DataGridViewPaintParts.ContentForeground)
            e.Handled = True
        End If
    End Sub
End Class