Option Strict On
 
Class Form1
 
  Dim Rect As New Rectangle(80, 45, 160, 90) 'Rechteck
  Dim Diff As Size 'angeklickte Differenz
  Dim DragRect As Boolean 'Maustaste gedrückt
 
  Private Sub PB1_MouseDown(sender As Object, e As MouseEventArgs) Handles _
    PB1.MouseDown
    If e.Button = MouseButtons.Left AndAlso Rect.Contains(e.Location) Then
      Diff.Width = e.X - Rect.X
      Diff.Height = e.Y - Rect.Y
      DragRect = True
    End If
  End Sub
 
  Private Sub PB1_MouseMove(sender As Object, e As MouseEventArgs) Handles _
    PB1.MouseMove
    If Rect.Contains(e.Location) Then
      Cursor.Current = Cursors.Hand
    Else
      Cursor.Current = Cursors.Default
    End If
 
    If Not DragRect Then Exit Sub
 
    ' Position berechnen
    Rect.Location = e.Location - Diff
 
    ' Rechteck begrenzen
    If Rect.X < 0 Then Rect.X = 0
    If Rect.Y < 0 Then Rect.Y = 0
    If Rect.X + Rect.Width > PB1.Width - 3 Then Rect.X = PB1.Width - 3 - _
      Rect.Width
    If Rect.Y + Rect.Height > PB1.Height - 3 Then Rect.Y = PB1.Height - 3 - _
    Rect.Height
 
    ' neu zeichnen
    PB1.Invalidate()
  End Sub
 
  Private Sub PB1_MouseUp(sender As Object, e As MouseEventArgs) Handles _
    PB1.MouseUp
    DragRect = False
  End Sub
 
  Private Sub PB1_Paint(sender As Object, e As PaintEventArgs) Handles PB1.Paint
    e.Graphics.DrawRectangle(Pens.Red, Rect)
  End Sub
 
End Class