' ImageList1 Images: 0 (Symbol Ordner)
'                    1 (Symbol geöffneter Ordner)
 
' Treeview1 - ImageList = "ImageList1"
'           - ImageIndex = 0
'           - SelectedImageIndex = 1
 
Imports System.IO
 
Public Class Form4
  Dim strDrv As String = "C:\"
 
  Public Class TreeNode
    Inherits System.Windows.Forms.TreeNode
    Public Path As String
  End Class
 
  Private Sub Form1_Load(sender As Object, e As System.EventArgs) Handles _
    Me.Load
    Dim tn As TreeNode = Nothing
    Dim nodeinfo As IO.DirectoryInfo = New IO.DirectoryInfo(strDrv)
 
    For Each di As DirectoryInfo In nodeinfo.GetDirectories()
      If di.Attributes = FileAttributes.Directory Then
        tn = AddNode(TreeView1.Nodes, di.Name, strDrv & di.Name)
        If Directory.GetDirectories(di.FullName).Length > 0 Then AddNode( _
          tn.Nodes, ".", ".")
      End If
    Next
  End Sub
 
  Private Sub TreeView1_BeforeExpand (sender As Object, e As _
    System.Windows.Forms.TreeViewCancelEventArgs) Handles TreeView1.BeforeExpand
    Dim tn As TreeNode = DirectCast(e.Node, TreeNode)
 
    If DirectCast(tn.Nodes(0), TreeNode).Path = "." Then Call CreateSubnodes(tn)
  End Sub
 
  Private Sub CreateSubnodes (ByVal node As TreeNode)
    Dim d As New DirectoryInfo(node.Path)
 
    node.Nodes.Clear()
 
    For Each di As DirectoryInfo In d.GetDirectories
      If di.Attributes = FileAttributes.Directory Then
        Dim tn As TreeNode = DirectCast(node, TreeNode)
        tn = AddNode(node.Nodes, Path.GetFileName(di.FullName), di.FullName)
        If Directory.GetDirectories(di.FullName).Length > 0 Then AddNode( _
          tn.Nodes, ".", ".")
        tn.ImageIndex = 0
        tn.SelectedImageIndex = 1
      End If
    Next
  End Sub
 
  Private Function AddNode (ByVal nodeCollection As TreeNodeCollection, ByVal _
    Caption As String, ByVal path As String) As TreeNode
    Dim tn As New TreeNode()
    tn.Text = Caption
    tn.Path = path
    nodeCollection.Add(tn)
    Return tn
  End Function
End Class