Public Class frmFader
 
    Dim bmp1, bmp2 As Bitmap
    Dim sz As Size = New Size(300, 300) 'Größe der Bildanzeige 
 
    Dim pb As New PictureBox With 
         {.Parent = Me, .Size = sz, .Top = 10, .Left = 10}
 
    Dim WithEvents tm As New Timer With {.Interval = 500, .Enabled = False}
 
 
    Private Sub frmFader_Load(sender As Object, e As EventArgs) Handles _
      MyBase.Load
 
        bmp1 = New Bitmap("G:\daten\x1.jpg")  'Hier zwei Bilddateien angeben
        bmp2 = New Bitmap("G:\daten\x2.jpg")
 
        'Bilder in Größe abschneiden (oder stretchen)
        'und Parameter vereinheitlichen (24er - 3 Byte pro Pixel)
        Using bmp As New Bitmap(sz.Width, sz.Height,
                System.Drawing.Imaging.PixelFormat.Format24bppRgb),
                g As Graphics = Graphics.FromImage(bmp)
 
            g.InterpolationMode = 
               Drawing2D.InterpolationMode.HighQualityBicubic
 
            g.DrawImage(bmp1, 0, 0, sz.Width, sz.Height)
            bmp1 = bmp.Clone
 
            g.DrawImage(bmp2, 0, 0, sz.Width, sz.Height)
            bmp2 = bmp.Clone
        End Using
 
        tm.Enabled = True
    End Sub
 
 
 
    Private Sub Fade(ByVal Alpha As Single)
        Dim ColMat As New System.Drawing.Imaging.ColorMatrix _
        With {.Matrix33 = Alpha}            ' 
        ' Farbmatrix anlegen
        Dim imgAtt As New System.Drawing.Imaging.ImageAttributes()              _
                           ' 
        ' Bildattribute anlegen
        imgAtt.SetColorMatrix(ColMat)
 
 
        Using bmp As New Bitmap(sz.Width, sz.Height),
                g As Graphics = Graphics.FromImage(bmp)
 
            g.DrawImage(bmp1, 0, 0, sz.Width, sz.Height)
 
            g.DrawImage(bmp2, New Rectangle(0, 0, sz.Width, sz.Height),
                        0, 0, sz.Width, sz.Height,
                        GraphicsUnit.Pixel, imgAtt)
 
            If pb.Image IsNot Nothing Then pb.Image.Dispose()
            pb.Image = bmp.Clone
        End Using
    End Sub
 
 
    Private Sub tm_Tick(sender As Object, e As EventArgs) Handles tm.Tick
 
        Static alpha As Single = 0
        alpha += 0.1
        If alpha > 1 Then alpha = 0
        Fade(alpha)
    End Sub
End Class