Imports System.IO
Imports System.IO.Compression
Imports System.Text
 
Module Module2
 
  Sub MeinTest()
    Dim sb As New StringBuilder
    For x = -32768 To 65535
      sb.Append(ChrW(x))
    Next
    Dim Eingabe As String = sb.ToString
 
    Dim OrigBytes As Byte() = Encoding.UTF8.GetBytes(Eingabe)
    Dim ComprBytes As Byte() = Compress(OrigBytes)
    Dim DecomprBytes As Byte() = Decompress(ComprBytes)
    Dim Ausgabe As String = Encoding.UTF8.GetString(DecomprBytes)
 
    Console.WriteLine("Länge Eingabe: {0}", Eingabe.Length)
    Console.WriteLine("Länge Ausgabe: {0}", Ausgabe.Length)
    Console.WriteLine()
    Console.WriteLine("Länge original Bytes: {0}", OrigBytes.Length)
    Console.WriteLine("Länge komprimierte Bytes: {0}", ComprBytes.Length)
    Console.WriteLine("Länge dekomprimierte Bytes: {0}", DecomprBytes.Length)
    Console.WriteLine()
    Console.WriteLine("Gleiche Bytes: {0}", OrigBytes.SequenceEqual( _
      DecomprBytes))
    Console.WriteLine("Gleicher Text: {0}", Eingabe = Ausgabe)
  End Sub
 
  Function Compress(ba As Byte()) As Byte()
    Using input As New MemoryStream(ba)
      Using output As New MemoryStream()
        Using gzip As New DeflateStream(output, CompressionMode.Compress)
          input.CopyTo(gzip)
        End Using
        Return output.ToArray
      End Using
    End Using
  End Function
 
  Function Decompress(ba As Byte()) As Byte()
    Using input As New MemoryStream(ba)
      Using output As New MemoryStream()
        Using gzip As New DeflateStream(input, CompressionMode.Decompress)
          gzip.CopyTo(output)
          Return output.ToArray
        End Using
      End Using
    End Using
  End Function
 
End Module