Attribute VB_Name = "BAS_INI"
Option Explicit
 
' INI-Dateien lesen / schreiben (Declares)
Public Declare Function WritePrivateProfileString Lib "kernel32" Alias _
                       "WritePrivateProfileStringA" (ByVal lpApplicationName As _
                       String, _
                                                     ByVal lpKeyName As Any, _
                                                     ByVal lpString As Any, _
                                                     ByVal lpFileName As _
                                                     String) As Long
 
Private Declare Function GetPrivateProfileString Lib "kernel32" Alias _
                        "GetPrivateProfileStringA" (ByVal lpApplicationName As _
                        String, _
                                                    ByVal lpKeyName As Any, _
                                                    ByVal lpDefault As String, _
                                                    ByVal lpReturnedString As _
                                                    String, _
                                                    ByVal nSize As Long, ByVal _
                                                    lpFileName As String) As _
                                                    Long
 
 ' Text (String) in INI-Datei schreiben
Public Function IniWriteString(ByVal Sektion As String, _
                               ByVal Titel As String, _
                               ByVal Inhalt As String, _
                               ByVal Datei As String) As Long
  If Dir$(Datei) = "" Then
    IniWriteMsgDoNotEdit Datei
  End If
  IniWriteString = WritePrivateProfileString(Sektion, Titel, Inhalt, Datei)
End Function
Public Sub IniWriteMsgDoNotEdit(ByVal Datei As String)
  Dim F As Integer
  F = FreeFile
  Open Datei For Output As #F
    Print #F, ";"
    Print #F, "; ###############################"
    Print #F, "; #                             #"
    Print #F, "; #  Do not work on this file!  #"
    Print #F, "; #                             #"
    Print #F, "; ###############################"
    Print #F, ";"
  Close #F
End Sub
 
 ' INI String löschen
Public Function IniDeleteString(ByVal Sektion As String, _
                                ByVal Titel As String, _
                                ByVal Datei As String) As Long
  IniDeleteString = WritePrivateProfileString(Sektion, Titel, vbNullString, _
    Datei)
End Function
 
 ' INI Abschnitt löschen
Public Function IniDeleteArray(ByVal Sektion As String, _
                               ByVal Datei As String) As Long
  IniDeleteArray = WritePrivateProfileString(Sektion, vbNullString, "", Datei)
End Function
 
' INI Abschnitte löschen
Public Function IniDeleteAllArray(ByVal Datei As String) As Long
  IniDeleteAllArray = WritePrivateProfileString(vbNullString, "", "", Datei)
End Function
 
 ' Text (String) aus INI-Datei lesen
Public Function IniReadString(ByVal Sektion As String, _
                              ByVal Titel As String, _
                              ByVal Vorgabe As String, _
                              ByVal Laenge As Integer, _
                              ByVal Datei As String) As String
  Dim Result As Long
  Dim Dummy As String
 
  Dummy = Space$(Laenge + 1)
  Result = GetPrivateProfileString(Sektion, Titel, Vorgabe, Dummy, Laenge, _
    Datei)
  IniReadString = Left$(Dummy, Result)
End Function
 
' Eintrag aus INI-Datei lesen
Public Function IniReadStringGet(ByVal Sektion As String, _
                                 ByVal Titel As String, _
                                 ByVal Vorgabe As String, _
                                 ByVal Datei As String, _
                                 Optional ByVal nSize As Integer = 256) As _
                                 String
  Dim lResult As Long
  Dim sValue As String
 
  sValue = Space$(nSize)
  lResult = GetPrivateProfileString(Sektion, Titel, Vorgabe, sValue, nSize, _
    Datei)
  IniReadStringGet = Left$(sValue, lResult)
End Function
 
' alle Abschnittsnamen ermitteln
Public Function IniGetArrays(ByVal Datei As String) As String 'Split( 
' IniGetArrays, vbNullChar)
  IniGetArrays = IniReadStringGet(vbNullString, "", "", Datei, 32767)
  ' BSP
  'Dim Data As String
  'Data = IniGetArrays(Programm_INI)
  'Dim Data2() As String
  'Data2 = Split(Data, vbNullChar)
  'Data2(0-x) = Abschnittsnamen
End Function
 
' alle Schlüsselnamen ermitteln
Public Function IniGetStrings(ByVal Sektion As String, _
                              ByVal Datei As String) As String 'Split( 
                              ' IniGetArrays, vbNullChar)
  IniGetStrings = IniReadStringGet(Sektion, vbNullString, "", Datei, 32767)
  ' BSP
  'Dim Data As String
  'Data = IniGetStrings("Sektion", Programm_INI)
  'Dim Data2() As String
  'Data2 = Split(Data, vbNullChar)
  'Data2(0-x) = Schlüsselnamen
End Function