' List the fields in this table.
Private Sub ListFields(ByVal db_file As String, ByVal db_table_name As String)
Dim statement As String
Dim conn As ADODB.Connection
Dim rs As ADODB.Recordset
 
    ' Open a connection.
    Set conn = New ADODB.Connection
    conn.ConnectionString = _
        "Provider=Microsoft.Jet.OLEDB.4.0;" & _
        "Data Source=" & db_file & ";" & _
        "Persist Security Info=False"
    conn.Open
 
    lstFields.Clear
 
    ' Use OpenSchema and get the table names.
    Set rs = conn.OpenSchema(adSchemaColumns, _
        Array(Empty, Empty, db_table_name))
 
    Do While Not rs.EOF
        lstFields.AddItem rs!COLUMN_NAME
        rs.MoveNext
    Loop
 
    rs.Close
    conn.Close
End Sub
 
' List the tables in the database.
Private Sub ListTables(ByVal db_name As String)
Dim statement As String
Dim conn As ADODB.Connection
Dim rs As ADODB.Recordset
 
    ' Open a connection.
    Set conn = New ADODB.Connection
    conn.ConnectionString = _
        "Provider=Microsoft.Jet.OLEDB.4.0;" & _
        "Data Source=" & db_name & ";" & _
        "Persist Security Info=False"
    conn.Open
 
    lstTables.Clear
    lstFields.Clear
 
    ' Use OpenSchema and get the table names.
    Set rs = conn.OpenSchema(adSchemaTables, _
        Array(Empty, Empty, Empty, "Table"))
    Do While Not rs.EOF
        lstTables.AddItem rs!TABLE_NAME
        rs.MoveNext
    Loop
 
    rs.Close
    conn.Close
End Sub