With DataReport1
    [...]
    Dim aDrucker As String
    aDrucker = Printer.DeviceName
    Call fSet_DefaultPrinter(RDrucker)
    PrintReport
    Call fSet_DefaultPrinter(aDrucker)
    [...]
End With

Option Explicit
 
Public Function fSet_DefaultPrinter( _
    ByVal sPrinterName As String) As Boolean
 
    Dim sComputerName As String
    Dim oWMI As Object
    Dim oPrinter As Object
    Dim colInstalledPrinters As Variant
 
    ' Fehlerbehandlung aktivieren
    On Error GoTo ErrHandler
 
    ' lokaler Rechner
    sComputerName = "."
 
    ' WMI-Objekt erstellen
    Set oWMI = GetObject("winmgmts:" _
                & "{impersonationLevel=impersonate}!\\" & _
                sComputerName & "\root\cimv2")
 
    ' WMI-Abfrage: alle Drucker mit dem
    ' einer bestimmten Bezeichnung selektieren
    Set colInstalledPrinters = oWMI.ExecQuery _
                                ("SELECT * FROM Win32_Printer WHERE Name = '" & _
                                sPrinterName & "'")
 
    ' Jetzt den Drucker als Standard-Drucker festlegen
    For Each oPrinter In colInstalledPrinters
        oPrinter.SetDefaultPrinter
    Next
 
    fSet_DefaultPrinter = True
    Exit Function
 
ErrHandler:
    fSet_DefaultPrinter = False
End Function