Option Explicit
' Hier wird ein Datensatz definiert
Private Type typAutodaten
    ModellName As String * 50
    Preis As Currency
    Geschwindigkeit As Single
    Farbe As String * 12
End Type
 
' Die Variable AutoDatenFeld nimmt die Datensätze auf
Private AutoDatenFeld(0 To 100) As typAutodaten
Private MaxDatenSatzNr As Integer
Private DatensatzNr As Integer
Private Updatemodus As Boolean
 
 
' Wird aufgerufen, wenn ein Hinzufügen abgebrochen
' werden soll
Private Sub cmdAbbrechen_Click()
    DatensatzNrAnzeigen
    cmdDatensatzhinzufügen.Caption = "&Hinzufügen"
    cmdAbbrechen.Enabled = False
    cmdDatensatzlöschen.Enabled = True
    Updatemodus = False
End Sub
 
' Wird aufgerufen, wenn ein Datensatz hinzugefügt wird
Private Sub cmdDatensatzHinzufügen_Click()
' Wenn noch kein Updatemodus aktiv, dann
' auf Updatemodus umschalten
    If Updatemodus = False Then
        lblDatensatzNr.Caption = MaxDatenSatzNr + 1
        cmdDatensatzhinzufügen.Caption = "&Aktualisieren"
        cmdAbbrechen.Enabled = True
        cmdDatensatzlöschen.Enabled = False
        EingabefelderLöschen
        Updatemodus = True
    Else
    ' Updatemodus aktiv, Datensatz an das Ende hängen
        MaxDatenSatzNr = MaxDatenSatzNr + 1
        DatensatzNr = MaxDatenSatzNr
        Datenaktualisieren
        DatensatzNrAnzeigen
        cmdDatensatzhinzufügen.Caption = "&Hinzufügen"
        cmdAbbrechen.Enabled = False
        cmdDatensatzlöschen.Enabled = True
        Updatemodus = False
    End If
End Sub
 
' Alle Eingabefelder löschen
Sub EingabefelderLöschen()
    txtGeschwindigkeit.Text = ""
    txtModellname.Text = ""
    txtPreis.Text = ""
    txtFarbe.Text = ""
    txtModellname.SetFocus
End Sub
 
' Wird aufgerufen, wenn ein Datensatz gelöscht werden soll
Private Sub cmdDatensatzLöschen_Click()
    Dim n As Integer
    If MaxDatenSatzNr > 0 Then
            For n = DatensatzNr To MaxDatenSatzNr - 1
                With AutoDatenFeld(n)
                .Geschwindigkeit = AutoDatenFeld(n + 1).Geschwindigkeit
                .ModellName = AutoDatenFeld(n + 1).ModellName
                .Preis = AutoDatenFeld(n + 1).Preis
            End With
        Next
        MaxDatenSatzNr = MaxDatenSatzNr - 1
        MovePrevious
    End If
End Sub