Private Declare Function SetWindowPos Lib "user32" _
    ( _
    ByVal hWnd As Long, _
    ByVal hWndInsertAfter As Long, _
    ByVal x As Long, _
    ByVal y As Long, _
    ByVal cx As Long, _
    ByVal cy As Long, _
    ByVal wFlags As Long _
    ) _
    As Long
 
Private Const HWND_TOPMOST = -1
Private Const SWP_NOACTIVATE = &H10
Private Const SWP_NOMOVE = &H2
Private Const SWP_NOSIZE = &H1
 
' Erzeugt das ToolTip-Fenster (mit einem weiteren Parameter)
Public Sub Create(ByVal hWndParent As Long, _
  Optional ByVal bAlwaysTip As Boolean = True, _
  Optional ByVal bBalloonTip As Boolean = True, _
  Optional ByVal bAlwaysOnTop As Boolean = True)
 
  Dim nFlags As Long
 
  ' Wir möchten kein normales Fenster
  nFlags = WS_POPUP Or TTS_NOPREFIX
 
  ' Falls der ToolTip auch bei deaktiviertem
  ' Control erscheinen soll...
  If bAlwaysTip Then nFlags = nFlags Or TTS_ALWAYSTIP
 
  ' Falls ein "moderner" Balloon-ToolTip erwünscht...
  If bBalloonTip Then nFlags = nFlags Or TTS_BALLOON
 
  ' Window-Handle erstellen
  m_hWnd = CreateWindowEx(0, "tooltips_class32", 0, _
    nFlags, CW_USEDEFAULT, CW_USEDEFAULT, CW_USEDEFAULT, _
    CW_USEDEFAULT, hWndParent, 0, App.hInstance, 0)
 
   '----Soll der ToolTip immer im Vordergrund erscheinen?---'
   If bAlwaysOnTop Then
    SetWindowPos m_hWnd, HWND_TOPMOST, 0, 0, 0, 0, _
          SWP_NOACTIVATE + SWP_NOMOVE + SWP_NOSIZE
   End If
  ' maximale Fensterbreite festlegen
  SendMessageLong m_hWnd, TTM_SETMAXTIPWIDTH, 0, m_lMaxWidth
End Sub