Private Declare Sub InitCommonControls Lib "comctl32.dll" ()
 
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" _
   (ByVal hWnd As Long, ByVal wMsg As Long, _
    ByVal wParam As Long, lParam As Any) As Long
 
Private Declare Function CreateWindowEx Lib "user32" Alias _
   "CreateWindowExA" (ByVal dwExStyle As Long, _
    ByVal lpClassName As String, ByVal lpWindowName As String, _
    ByVal dwStyle As Long, ByVal x As Long, ByVal y As Long, _
    ByVal nWidth As Long, ByVal nHeight As Long, _
    ByVal hWndParent As Long, ByVal hMenu As Long, _
    ByVal hInstance As Long, lpParam As Any) As Long
 
Private Declare Function DestroyWindow Lib "user32" (ByVal hWnd As Long) As Long
 
Private Type RECT
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type
 
Private Type TOOLINFO
  cbSize As Long
  uFlags As Long
  hWnd As Long
  uId As Long
  rec As RECT
  hinst As Long
  lpszText As String
  lParam As Long
  lpReserved As Long
End Type
 
Private Const WM_USER = &H400
Private Const TTM_ADDTOOL = WM_USER + 4
Private Const TTM_SETMAXTIPWIDTH = WM_USER + 24
Private Const TTF_IDISHWND = &H1
Private Const TTF_SUBCLASS = &H10
 
Private hWndToolTipWin As Long
 
Private Sub Form_Load()
    ' Form wird mit doppelzeiligen Tooltips ausgestattet
    InitCommonControls
    hWndToolTipWin = CreateWindowEx(0, "tooltips_class32", "", _
                         0, 0, 0, 0, 0, 0, 0, 0, ByVal 0)
    SendMessage hWndToolTipWin, TTM_SETMAXTIPWIDTH, 0, 300
 
    ' ToolTipps zuweisen
    AddToolTip Text1.hWnd, "Das ist ein langer Text" & Chr(13) & "mit Tooltipp"
End Sub
 
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
    DestroyWindow hWndToolTipWin
End Sub
 
Private Sub AddToolTip(ByVal hWnd As Long, ByVal sToolTipp As String)
    Dim udtTool As TOOLINFO
 
    With udtTool
       .cbSize = Len(udtTool)
       .hWnd = hWnd
       .uFlags = TTF_IDISHWND Or TTF_SUBCLASS
       .uId = hWnd
       .lpszText = sToolTipp
    End With
 
    SendMessage hWndToolTipWin, TTM_ADDTOOL, 0, udtTool
End Sub