Option Explicit
 
Const PDH_CSTATUS_VALID_DATA = &H0
Const PDH_CSTATUS_NEW_DATA = &H1
 
Private Declare Function PdhOpenQuery Lib "PDH.DLL" (ByVal Reserved As Long, _
  ByVal dwUserData As Long, ByRef hQuery As Long) As Long
Private Declare Function PdhCloseQuery Lib "PDH.DLL" (ByVal hQuery As Long) As _
Long
Private Declare Function PdhVbAddCounter Lib "PDH.DLL" (ByVal QueryHandle As _
Long, ByVal CounterPath As String, ByRef CounterHandle As Long) As Long
Private Declare Function PdhCollectQueryData Lib "PDH.DLL" (ByVal QueryHandle _
As Long) As Long
Private Declare Function PdhVbGetDoubleCounterValue Lib "PDH.DLL" (ByVal _
CounterHandle As Long, ByRef CounterStatus As Long) As Double
 
Dim hQuery As Long
Dim hCounter As Long
Dim RetVal As Long
 
Private Sub Form_Load()
    RetVal = PdhOpenQuery(0, 1, hQuery)
    If RetVal <> 0 Then
        MsgBox "Fehler beim Öffnen der Query", vbExclamation, "Fehler!"
        End
    End If
    RetVal = PdhVbAddCounter(hQuery, "\Prozessor(0)\Prozessorzeit (%)", _
      hCounter)
    If RetVal <> 0 Then
        MsgBox "Fehler beim Hinzufügen des Counters", vbExclamation, "Fehler!"
        PdhCloseQuery hQuery
        End
    End If
    Timer1.Interval = 500
    Timer1.Enabled = True
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    PdhCloseQuery hQuery
End Sub
 
Private Sub Timer1_Timer()
    Dim dblValue As Double
    Dim pdhStatus As Long
 
    PdhCollectQueryData hQuery
    dblValue = PdhVbGetDoubleCounterValue(hCounter, pdhStatus)
 
    If (pdhStatus = PDH_CSTATUS_VALID_DATA) Or (pdhStatus = _
      PDH_CSTATUS_NEW_DATA) Then
        Label1.Caption = "CPU-Auslastung: " + Format(dblValue, "0.00")
    End If
End Sub

Gru? Michi aus Hannover

1 + 1 = 3 f?r hinreichend gro?e 1