Function IniReadPvtString(ByVal Section As String, ByVal Entry As String, ByVal _
  Default As String, ByVal IniFile As String) As String
  Dim ret As Long
  Dim s As String
 
  s = Space$(255)
  ret = GetPrivateProfileString(ByVal Section, ByVal Entry, ByVal Default, _
    ByVal s, 255, ByVal IniFile)
  IniReadPvtString = Asciiz2String(s)
End Function
 
Function Asciiz2String(asciiz As String) As String
  Dim PosNull As Integer
 
  For PosNull = 1 To Len(asciiz)
    If Asc(Mid$(asciiz, PosNull, 1)) = 0 Then Exit For
  Next PosNull
  Asciiz2String = Left$(asciiz, PosNull - 1)
End Function
 
Sub GrößeLesen(frm As Form, ByVal Eintrag As String)
  Dim s As String
 
  If Eintrag = "" Then Eintrag = "WindowPos"
  s = IniReadPvtString(CStr(App.Title), Eintrag, "", "d:\IBSPOS.ini")
  If s = "" Then
    frm.Move 0, 0
  Else
    frm.Move Val(ItemExtract(2, s, ",")), Val(ItemExtract(1, s, ","))
    On Error Resume Next
    If Not frm.MDIChild Then
      frm.Height = Val(ItemExtract(3, s, ","))
      frm.Width = Val(ItemExtract(4, s, ","))
    End If
    On Error GoTo 0
    frm.CboZoom.ListIndex = Val(ItemExtract(5, s, ","))
  End If
End Sub
 
Sub GrößeSpeichern(frm As Form, ByVal Eintrag As String)
  Dim s As String, Titel As String
  Dim ret As Long
 
  If Eintrag = "" Then Eintrag = "WindowPos"
  If frm.Top < 0 Or frm.Left < 0 Then
    s = Trim(0 & "," & 0 & "," & Str$(frm.Height) & "," & Str$(frm.Width) & "," _
      & Str$(frm.CboZoom.ListIndex) & "," & Str$(frm.WindowState))
  Else
    s = Trim(Str$(frm.Top) & "," & Str$(frm.Left) & "," & Str$(frm.Height) & _
      "," & Str$(frm.Width) & "," & Str$(frm.CboZoom.ListIndex) & "," & Str$( _
      frm.WindowState))
  End If
  Titel = App.Title
  ret = WritePrivateProfileString(ByVal Titel, ByVal Eintrag, ByVal s, ByVal _
    "d:\IBSPOS.ini")
End Sub