Option Explicit
 
Private Const c_ZeitBasis As Long = 100
Private Const c_ZeitFak As Single = c_ZeitBasis / 1000
Private Const c_StundenFak As Single = 3600 / c_ZeitFak
Private Const c_MinutenFak As Single = 60 / c_ZeitFak
Private Const c_SekundenFak As Single = 1 / c_ZeitFak
 
Private Const c_CapStartTaste As String = "Start"
Private Const c_CapPausenTaste_ZeitLaeuft As String = "Pause"
Private Const c_CapPausenTaste_ZeitSteht As String = "Weiter"
Private Const c_CapStopTaste As String = "Stop"
 
Private m_MeinZeitZaehler As Long
 
Private Sub cmdPause_Click()
 
  cmdStart.Enabled = False
  cmdPause.Enabled = True
  cmdStop.Enabled = True
 
  cmdPause.Caption = IIf(Timer1.Enabled, c_CapPausenTaste_ZeitSteht, _
    c_CapPausenTaste_ZeitLaeuft)
 
  Timer1.Enabled = Not Timer1.Enabled
 
End Sub
 
Private Sub cmdStart_Click()
  m_MeinZeitZaehler = 0
 
  cmdStart.Enabled = False
  cmdPause.Enabled = True
  cmdStop.Enabled = True
 
  Timer1.Enabled = True
 
End Sub
 
Private Sub cmdStop_Click()
  Timer1.Enabled = False
 
  cmdStart.Enabled = True
  cmdPause.Enabled = False
  cmdStop.Enabled = False
 
  cmdPause.Caption = c_CapPausenTaste_ZeitLaeuft
 
End Sub
 
Private Sub Form_Load()
 
  m_MeinZeitZaehler = 0
 
  Timer1.Interval = c_ZeitBasis
  Timer1.Enabled = False
 
  cmdStart.Caption = c_CapStartTaste
  cmdPause.Caption = c_CapPausenTaste_ZeitLaeuft
  cmdStop.Caption = c_CapStopTaste
 
  cmdPause.Enabled = False
  cmdStop.Enabled = False
 
  Label1.Caption = "00:00:00"
 
End Sub
 
Private Sub Timer1_Timer()
 
  Dim strZeit As String
  Dim Stunden As Integer
  Dim Minuten As Integer
  Dim Sekunden As Single
  Dim Rest As Long
 
  m_MeinZeitZaehler = m_MeinZeitZaehler + 1
 
  Debug.Assert m_MeinZeitZaehler <> 100
 
  Stunden = m_MeinZeitZaehler \ c_StundenFak        'Man achte auf den Operator 
  ' \
  Rest = m_MeinZeitZaehler - Stunden * c_StundenFak
 
  Minuten = Rest \ c_MinutenFak                     'Man achte auf den Operator 
  ' \
  Rest = Rest - Minuten * c_MinutenFak
 
  Sekunden = Rest / c_SekundenFak                   'Hier der andere
 
  strZeit = IIf(Stunden < 10, "0", vbNullString) & CStr(Stunden) & ":" & _
            IIf(Minuten < 10, "0", vbNullString) & CStr(Minuten) & ":" & _
            IIf(Sekunden < 10#, "0", vbNullString) & CStr(Sekunden)
 
  Debug.Assert InStr(strZeit, "-") = 0
 
  Label1.Caption = strZeit
 
End Sub

Gruß
Dirk

--
?Get it right the first time