<code><font color=green>' Auflistung ausdrucken</font>
Private Sub cmdPrint_Click()
  Dim I As Integer
 
  Screen.MousePointer = 11
  With Printer
    .ScaleMode = 6    <font color=green>' Maßeinheit "mm"</font>
 
    .Font.Name = "Arial"
    .Font.Size = 12
 
    .CurrentX = 20
    .CurrentY = 20
    .Font.Bold = True
    Printer.Print "POSITIONEN" + vbCrLf
    .Font.Bold = False
 
    <font color=green>' Listenkopf</font>
    .Font.Bold = True
    .Font.Size = 10
    .CurrentX = 20: Printer.Print "Pos";
    .CurrentX = 30: Printer.Print "Artikelnummer";
    .CurrentX = 70: Printer.Print FillToMaxSize("Preis", 20);
    .CurrentX = 100: Printer.Print FillToMaxSize("Menge", 20);
    .CurrentX = 130: Printer.Print FillToMaxSize("Gesamt", 25)
    .Font.Bold = False
 
    <font color=green>' Artikelpositionen</font>
    .CurrentY = .CurrentY + 5
    For I = 1 To ListView1.ListItems.Count
      .CurrentX = 20: Printer.Print FillToMaxSize(Format$(I), 5);
      .CurrentX = 30: Printer.Print ListView1.ListItems(I).Text;
      .CurrentX = 70: Printer.Print FillToMaxSize(ListView1.ListItems( _
        I).SubItems(1), 20);
      .CurrentX = 100: Printer.Print FillToMaxSize(ListView1.ListItems( _
      I).SubItems(2), 20);
      .CurrentX = 130: Printer.Print FillToMaxSize(ListView1.ListItems( _
      I).SubItems(3), 25)
    Next I
 
    <font color=green>' Gesamtsumme</font>
    .CurrentY = .CurrentY + 5
    .Font.Bold = True
    .CurrentX = 100: Printer.Print FillToMaxSize("Gesamt:", 20);
    .CurrentX = 130: Printer.Print FillToMaxSize(lblSumme.Caption, 25)
    .Font.Bold = False
 
    <font color=green>' Druckauftrag beenden</font>
    .EndDoc
  End With
  Screen.MousePointer = 0
 
  MsgBox "Artikel-Auflistung wurde ausgedruckt!", 64, "Drucken..."
End Sub
 
<font color=green>' Auf bestimmte Länge auffüllen (für den Ausdruck)
' (rechtsbündig)</font>
Private Function FillToMaxSize(ByVal sText As String, ByVal mm As Integer) As _
  String
  With Printer
    While .TextWidth(sText) < mm
      sText = " " + sText
    Wend
  End With
  FillToMaxSize = sText
End Function</code>