Option Explicit
 
Private Sub Form_Load()
  Dim I As Long
 
  With Grid1
    .DataMode = Mode_List
    .ColumnAdd , "Spalte 1"
    .ColumnAdd , "Spalte 2"
    For I = 1 To 100
      .AddItem "Eintrag " & CStr(I) & vbTab & "Row" & CStr(I) & ",Col2"
    Next I
    .WheelMouse = False
    .OLEDropMode = Manuell
    .AllowMultiSelect = True
  End With
 
  With Grid2
    .DataMode = Mode_List
    .ColumnAdd , "Spalte 1"
    .ColumnAdd , "Spalte 2"
    .WheelMouse = False
    .OLEDropMode = Manuell
  End With
End Sub

Private Sub Grid1_CellClick(ByVal nRow As Long, ByVal nCol As Long, ByVal _
  Button As Integer, ByVal Shift As Integer)
  If Button = vbRightButton Then
    ' bei Rechtsklick - Drag-Vorgang starten
    Grid1.OLEDrag
  End If
End Sub

Private Sub Grid1_OLEStartDrag(Data As DataObject, AllowedEffects As Long)
  Dim I As Integer
 
  ' Erlaubte Aktionen festlegen
  AllowedEffects = vbDropEffectCopy Or vbDropEffectMove
 
  ' Daten-Format festlegen
  Data.SetData , vbCFFiles
 
  ' Einträge hinzufügen
  For I = 0 To Grid1.SelCount - 1
    Data.Files.Add Grid1.List(Grid1.SelRow(I))
  Next I
End Sub

Private Sub Grid2_OLEDragDrop(Data As DataObject, Effect As Long, Button As _
  Integer, Shift As Integer, X As Single, Y As Single)
  Dim I As Integer
 
  Dim nRow As Long
  nRow = Grid2.GetRowFromCursor
 
  ' Prüfen, ob es sich um korrekte Daten handelt
  If Data.GetFormat(vbCFFiles) Then
    ' alle Einträge (1 bis Files.Count)
    For I = 1 To Data.Files.Count
      ' Dateiname der Listbox hinzufügen
      Grid2.AddItem Data.Files(I), nRow
    Next I
  End If
End Sub

_________________________
Professionelle Entwicklerkomponenten
www.tools4vb.de