Option Explicit
 
Const db_file As String = "F:\Eigene" & _
  "Dateien\VB\Debug\DataGrid2\ForeignKeyNULL\db1.mdb"
 
Dim DB As DAO.Database
Dim MasterRS As DAO.Recordset
 
Private Sub Check1_Click()
    If Check1.Value = 1 Then
        'Aktiviere ComboBox
        sevGrid1.Columns("ForeignKey").ColType = TYPE_COMBOLIST
        sevGrid1.Refresh    'nötig um die RowLoaded-Ereignisse auszulösen
    Else
        'Deaktiviere ComboBox
        sevGrid1.Columns("ForeignKey").ColType = TYPE_TEXT
        sevGrid1.Refresh
    End If
End Sub
 
Private Sub Form_Load()
    On Error GoTo ErrorHandler
    'Datenbank öffnen
    Set DB = DBEngine.OpenDatabase(db_file)
    'Form-globalen Recordset auf die MasterTabelle öffnen
    Set MasterRS = DB.OpenRecordset("MasterTabelle", dbOpenSnapshot)
    'Grid einrichten und Recordset auf DetailTabelle zuweisen
    With sevGrid1
        .DataMode = Mode_Recordset
        .AllowEdit = True
        Set .Recordset = DB.OpenRecordset("SELECT * FROM DetailTabelle;")
        .Refresh
    End With
    Exit Sub
ErrorHandler:
    MsgBox Err.Number & ": " & Err.Description, vbCritical, "Fehler", _
      Err.HelpFile, Err.HelpContext
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    On Error Resume Next
    MasterRS.Close
    DB.Close
End Sub
 
Private Sub sevGrid1_ErrorUpdate(ByVal nRow As Long, ByVal nCol As Long, ByVal _
  sText As String, ByVal nError As Long, ByVal sDescription As String)
    MsgBox nError & ": " & sDescription
End Sub
 
Private Sub sevGrid1_FillComboBox(ByVal nRow As Long, ByVal nCol As Long, _
  oComboBox As sevDataGrid2.EditComboBox)
    'Werte aus der MasterTabelle füllen
    With oComboBox
'        'So wäre es einfach:
'        Set .Recordset = DB.OpenRecordset("SELECT * FROM MasterTabelle;")
        'Aber wir wollen ja auch die Möglichkeit, die Auswähl zu löschen:
        Set .Recordset = DB.OpenRecordset("SELECT '' AS Key, '' AS MasterText" & _
          "FROM MasterTabelle UNION SELECT Key, MasterText FROM MasterTabelle;")
        .ColVisible("Key") = False
        .ColVisible("MasterText") = True
        .BoundColumn = 1
        .DisplayColumn = 2
    End With
End Sub
 
Private Sub sevGrid1_RowLoaded(ByVal nRow As Long, Item As _
  sevDataGrid2.ListItem)
    If Check1.Value = 1 Then
        'Numerischen Schlüssel durch den Text ersetzen
        If Item.CellText("ForeignKey") = "" Then
            'Kein Fremdschlüssel zugewiesen -> Leer anzeigen
            Item.CellText("ForeignKey") = ""
        Else
            MasterRS.FindFirst "Key = " & Item.CellText("ForeignKey")
            If MasterRS.EOF Then
                Item.CellText("ForeignKey") = ""
            Else
                Item.CellText("ForeignKey") = MasterRS.Fields( _
                  "MasterText").Value
            End If
        End If
    End If
End Sub

Immer noch auf der Suche nach dem "Tu's trotzdem"-Button...