Public Class frmDrawRect
 
    Dim WithEvents btnDrawRect As New Button With _
        {.Parent = Me, .Text = "Zeichne Rechteck", .Width = 150}
    Dim WithEvents pb As New PictureBox With _
        {.Parent = Me, .Top = 50, .Size = New Size(300, 300), _
         .SizeMode = PictureBoxSizeMode.CenterImage}
 
    Dim DrawRect As Boolean = False
 
 
    Private Sub frmDrawRect_Load(sender As System.Object, _
        e As System.EventArgs) Handles MyBase.Load
 
        Me.Size = New Size(350, 400)
        Dim bmp As New Bitmap(250, 250)
        Using g As Graphics = Graphics.FromImage(bmp)
            g.Clear(Color.LightGray)
        End Using
        pb.Image = bmp
    End Sub
 
 
    Private Sub pb_Paint(sender As Object, _
        e As System.Windows.Forms.PaintEventArgs) Handles pb.Paint
 
        With e.Graphics
            Using p As New Pen(Color.Green, 4)
                .DrawEllipse(p, New Rectangle(New Point(0, 0), pb.Size))
                If DrawRect Then
                    Dim rect As New Rectangle(New Point(60, 60), New Size(130, _
                      130))
                    .DrawRectangle(p, rect)
                End If
            End Using
        End With
    End Sub
 
    Private Sub btnDrawRect_Click(sender As Object, _
        e As System.EventArgs) Handles btnDrawRect.Click
 
        DrawRect = Not DrawRect
        btnDrawRect.Text = _
            If(DrawRect, "Entferne Rechteck", "Zeichne Rechteck")
        pb.Invalidate()
    End Sub
End Class