Public Class frmExpressionColumn
 
    Dim WithEvents btnLoad As New Button With _
        {.Parent = Me, .Text = "Laden"}
 
    Dim dt As cDataTableCSV, bs As New BindingSource
 
    Dim dgv As New DataGridView With _
        {.Parent = Me, .Top = 50, .Width = 300, _
         .DataSource = bs, .ColumnHeadersHeight = 40}
 
 
    Private Sub btnLoad_Click(sender As Object, _
                              e As System.EventArgs) Handles btnLoad.Click
 
        If dt IsNot Nothing Then
            'geladene Tabelleninstanz entsorgen
            dt.Clear() : dt.Dispose() : dt = Nothing
        End If
        bs.DataSource = Nothing
 
        dt = New cDataTableCSV
 
        Dim AlterInTagen As String = _
            "AlterInTagen (am " & Today.ToString("dd.MM.yy") & ")"
        Const TageBisGeburtstag As String = "TageBisGeburtstag"
 
        If Not dt.LoadFile _
            ("C:\daten\birthday.csv", System.Text.Encoding.UTF8) Then
 
            MsgBox("Datei konnte nicht geladen werden", MsgBoxStyle.Exclamation)
        Else
            'Spaltenbezeichnung anpassen
            dt.Columns(0).ColumnName = "Name"
            dt.Columns(1).ColumnName = "Geburtstag"
 
            'zusätzliche Spalte
            dt.Columns.Add(AlterInTagen, GetType(Integer))
            dt.Columns(AlterInTagen).AllowDBNull = True
 
            dt.Columns.Add(TageBisGeburtstag, GetType(Integer))
 
            Dim gt As Date
            For i As Integer = 0 To dt.Rows.Count - 1
               If Date.TryParse(dt.Rows(i)("Geburtstag").ToString, gt) Then
                  dt.Rows(i)(AlterInTagen) = _
                  (Today.Date.Ticks - gt.Date.Ticks) / TimeSpan.TicksPerDay
 
                  'nächste Geburtstagsfeier im aktuellen oder im nächsten Jahr 
                  Dim gta As Date = New Date(Today.Year, gt.Month, gt.Day)
                  If gta < Today.Date Then gta = gta.AddYears(1)
 
                  dt.Rows(i)(TageBisGeburtstag) = _
                  (gta.Date.Ticks - Today.Date.Ticks) / TimeSpan.TicksPerDay
                Else
 
                    'ungültiger Eintrag in Spalte Geburtstag
                    dt.Rows(i)(AlterInTagen) = DBNull.Value
                    dt.Rows(i)(TageBisGeburtstag) = DBNull.Value
                End If
            Next i
 
            'Datenbindung erstellen
            bs.DataSource = dt
        End If
 
    End Sub
End Class