Public Class frmFilterAggregate
 
    Dim dt As New DataTable
    Dim bs As New BindingSource
    Dim dgv As New DataGridView With _
        {.Parent = Me, .DataSource = bs}
 
    Private Sub frmFilterAggregate_Load(sender As Object, _
        e As EventArgs) Handles MyBase.Load
 
        'Testspalten und Testdaten
        With dt.Columns
            .Add("ID", GetType(Integer))
            .Add("Datum", GetType(DateTime))
            .Add("Einnahmen", GetType(Decimal))
            .Add("Ausgaben", GetType(Decimal))
        End With
 
        Dim cal As System.Globalization.Calendar =
            System.Globalization.CultureInfo.InvariantCulture.Calendar
 
        With dt.Rows
            For i As Integer = 1 To 1000
                .Add(i, Randomdate(New DateTime(2000, 1, 1, cal)),
                     RandomMoney(100, 1000), RandomMoney(100, 1000))
            Next i
        End With
 
        'zu filterndes Jahr
        Dim year As Integer = 2000
 
        'Tabelle mit aggregierten Werten
        Dim dtx As New DataTable With {.TableName = "DTX"}
        dtx.Columns.Add("Monat")
        dtx.Columns.Add("Einnahmen", GetType(Decimal))
        dtx.Columns.Add("Ausgaben", GetType(Decimal))
 
        'Monats-Zeilen erstellen
        For r As Integer = 1 To 12
            dtx.Rows.Add(r, 0, 0)
        Next r
 
        'monatsbezogene Summen bilden
        For i As Integer = 0 To dt.Rows.Count - 1
 
            Dim datum As DateTime = _
               DirectCast(dt.Rows(i)("Datum"), DateTime)
 
            If datum.Year = year Then
                Dim sum As Decimal = _
                    CDec(dtx.Rows(datum.Month - 1)("Einnahmen"))
                sum += CDec(dt.Rows(i)("Einnahmen"))
                dtx.Rows(datum.Month - 1)("Einnahmen") = sum
 
                sum = CDec(dtx.Rows(datum.Month - 1)("Ausgaben"))
                sum += CDec(dt.Rows(i)("Ausgaben"))
                dtx.Rows(datum.Month - 1)("Ausgaben") = sum
            End If
        Next i
 
        bs.DataSource = dtx
    End Sub
 
 
    Dim rndm As New Random(1234)
 
    Private Function Randomdate(ByVal start As DateTime) As DateTime
        Return start.AddDays(rndm.Next(0, 1000))
    End Function
 
 
    Private Function RandomMoney(min As Decimal, _
        max As Decimal) As Decimal
 
        Return CDec(min + rndm.NextDouble * (max - min))
    End Function
 
End Class