Option Infer On
Public Class frmLinqGroup
    Dim dt As New DataTable
 
    Dim cht As New System.Windows.Forms.DataVisualization.Charting.Chart With
    {.Parent = Me, .Size = New Size(400, 400)}
 
 
    Private Sub frmLinqGroup_Load(sender As Object,
                                  e As EventArgs) Handles MyBase.Load
 
        'Testdaten
        dt.Columns.Add("Datum", GetType(Date))
        dt.Columns.Add("Anwesend", GetType(Integer))
 
        Dim basedate As Date = CDate("2.5.2016")
        Dim minutes() As Integer = {320, 410, 490}
        Dim rndm As New Random(12345)
 
        For i As Integer = 0 To 1000
            Dim dtx As Date = basedate.AddDays(i)
            Dim min As Integer = minutes(rndm.Next(0, 3))
            If dtx.DayOfWeek.Equals(DayOfWeek.Saturday) OrElse
               dtx.DayOfWeek.Equals(DayOfWeek.Sunday) Then min = 0
            dt.Rows.Add(dtx, min)
        Next i
 
        'Gruppieren der Anwesenheitstage pro Monat        
        Dim q = From row As DataRow In dt.AsEnumerable
                Let mnt As String = DateAndTime.MonthName(DirectCast(row( _
                  "Datum"), Date).Month)
                Let yr As Integer = DirectCast(row("Datum"), Date).Year
                Let anw As Boolean = DirectCast(row("Anwesend"), Integer) > 0
                Where anw
                Group By yr, mnt Into Group, Count()
 
 
        'optional: Aufbereitung der Abfrage als Tabelle
        Dim dtb As New DataTable
        dtb.Columns.Add("year-mnt", GetType(String))
        dtb.Columns.Add("count", GetType(Integer))
 
        For Each at In q
            With at
                'anonymer Typ in Datatable-Zeile, Jahr-Monat zusammenbauen
                dtb.Rows.Add(.yr.ToString & "-" & .mnt, .Count)
            End With
        Next at
 
        'Einrichtung des Chart
        With cht
            .DataSource = dtb
            .ChartAreas.Add("Base")
            .ChartAreas("Base").AxisX.Interval = 1
 
            .DataSource = dtb
 
            .Series.Add("Anw")
            With .Series("Anw")
                .XValueMember = "year-mnt"
                .YValueMembers = "Count"
                .ChartArea = "Base"
                .ChartType = DataVisualization.Charting.SeriesChartType.Bar
            End With
 
            .Titles.Add("Anwesenheitstage pro Monat")
 
        End With
    End Sub
End Class