Public Function AutoSizeImage(ByVal oBitmap As Image, _
ByVal maxWidth As Integer, _
ByVal maxHeight As Integer, _
Optional ByVal bStretch As Boolean = False) As Image
        GC.Collect()
        Try
            ' Größenverhältnis der max. Dimension
            Dim maxRatio As Single = CSng(maxWidth / maxHeight)
 
            ' Bildgröße und aktuelles Größenverhältnis
            Dim imgWidth As Integer = oBitmap.Width
            Dim imgHeight As Integer = oBitmap.Height
            Dim imgRatio As Single = CSng(imgWidth / imgHeight)
 
            ' Bild anpassen?
            If (imgWidth > maxWidth Or imgHeight > maxHeight) Or (bStretch) Then
                If imgRatio <= maxRatio Then
                    ' Größenverhältnis des Bildes ist kleiner als die
                    ' maximale Größe, in der das Bild angezeigt werden kann.
                    ' In diesem Fall muss die Bildbreite angepasst werden.
                    imgWidth = CInt(imgWidth / (imgHeight / maxHeight))
                    imgHeight = maxHeight
                Else
                    ' Größenverhältnis des Bildes ist größer als die 
                    ' maximale Größe, in der das Bild angezeigt werden kann.
                    ' In diesem Fall muss die Bildhöhe angepasst werden.
                    imgHeight = CInt(imgHeight / (imgWidth / maxWidth))
                    imgWidth = maxWidth
                End If
 
                ' Bitmap-Objekt in der neuen Größe erstellen
                Dim oImage As New Bitmap(imgWidth, imgHeight)
 
                ' Bild interpolieren, damit die Qualität erhalten bleibt
                Using g As Graphics = Graphics.FromImage(oImage)
                    g.InterpolationMode = _
                      Drawing2D.InterpolationMode.HighQualityBicubic
                    g.DrawImage(oBitmap, New Rectangle(0, 0, imgWidth, _
                    imgHeight))
                End Using
 
                ' neues Bitmap zurückgeben
                Return oImage
            Else
                ' unverändertes Originalbild zurückgeben
                Return oBitmap
            End If
        Catch ex As Exception
            DebugToFile(ex.Message)
            Return Nothing
        End Try
 
    End Function