Public Class frmByteFormatting
 
    Dim bsFiles As New BindingSource
    Dim WithEvents dgvFiles As New DataGridView With {.Parent = Me, .DataSource _
      = bsFiles}
    Dim dtFiles As New DataTable
 
 
    Private Sub frmByteFormatting_Load(sender As Object, e As EventArgs) _
      Handles MyBase.Load
 
        Dim basefolder As String = "G:\daten"  ' Ordner mit Dateien angeben
 
        dtFiles.Columns.Add("Filename", GetType(String))
        dtFiles.Columns.Add("Length", GetType(Integer))
 
        'Dateinamen und Länge in Table eintragen
        For Each file As String In IO.Directory.EnumerateFiles _
            (basefolder, "*.*", IO.SearchOption.TopDirectoryOnly)
 
            dtFiles.Rows.Add(IO.Path.GetFileName(file), New IO.FileInfo( _
              file).Length)
        Next file
 
        'Datenbindung
        bsFiles.DataSource = dtFiles
 
        'Grid einrichten
        dgvFiles.AllowUserToAddRows = False
 
        dgvFiles.Columns("Length").DefaultCellStyle.Alignment =
            DataGridViewContentAlignment.MiddleRight
 
    End Sub
 
 
    Private Sub dgvFiles_CellFormatting(sender As Object,
        e As DataGridViewCellFormattingEventArgs) Handles _
          dgvFiles.CellFormatting
 
        If e.ColumnIndex = 1 Then
            Dim vl As String
            Dim row As DataRow = bsFiles(e.RowIndex).row
            Dim length As Integer = CInt(row.Item("Length"))
            If length < 1024 Then
                vl = length.ToString & "  B"
            ElseIf length < 1024 * 1024 Then
                vl = CInt(length / 1024).ToString & " KB"
            Else
                vl = CInt(length / 1024 / 1024).ToString & " MB"
            End If
 
            e.Value = vl
            e.FormattingApplied = True
        End If
    End Sub
 
 
    Private Sub dgvFiles_SortCompare(sender As Object,
        e As DataGridViewSortCompareEventArgs) Handles dgvFiles.SortCompare
 
        If e.Column.Name <> "Length" Then Exit Sub
 
        Dim row1 As DataRow = bsFiles(e.RowIndex1).row
        Dim row2 As DataRow = bsFiles(e.RowIndex2).row
 
        e.SortResult = CInt(row1("Length")).CompareTo(CInt(row2("Length")))
        e.Handled = True
    End Sub
 
End Class