Public Class LineControl
    Inherits System.Windows.Forms.Control
    Public Enum Richtung
        Horizontal = 0
        Vertikal = 1
    End Enum
    Private components As System.ComponentModel.IContainer
    Private licol As Color = Color.Black
    Private lirich As Richtung = Richtung.Horizontal
    Private libreit As Integer = 5
    Public Sub New()
        MyBase.New()
        InitializeComponent()
        Init()
    End Sub
    Property LinienFarbe() As Color
        Get
            Return licol
        End Get
        Set(ByVal Value As Color)
            licol = Value
            Invalidate()
        End Set
    End Property
    Property LinienBreite() As Integer
        Get
            Return libreit
        End Get
        Set(ByVal Value As Integer)
            If Value < 1 Then
                Value = 1
            Else
                libreit = Value
                NeueGroesse()
                Invalidate()
            End If
        End Set
    End Property
    Property LinienRichtung() As Richtung
        Get
            Return lirich
        End Get
        Set(ByVal Value As Richtung)
            lirich = Value
            NeueGroesse()
            Invalidate()
        End Set
    End Property
    Protected Overloads Overrides Sub Dispose(ByVal disposing As Boolean)
        If disposing Then
            If Not (components Is Nothing) Then
                components.Dispose()
            End If
        End If
        MyBase.Dispose(disposing)
    End Sub
    Private Sub NeueGroesse()
        If lirich = Richtung.Horizontal Then
            Me.Height = libreit
            If Me.Width < 1 Then
                Me.Width = 1
            End If
        Else
            Me.Width = libreit
            If Me.Height < 1 Then
                Me.Height = 1
            End If
        End If
    End Sub
    Private Sub LineControl_Resize(ByVal sender As Object, ByVal e As _
      System.EventArgs) Handles MyBase.Resize
        NeueGroesse()
        Invalidate()
    End Sub
    Private Sub Init()
        Me.SetStyle(ControlStyles.DoubleBuffer Or ControlStyles.UserPaint Or _
          ControlStyles.AllPaintingInWmPaint, True)
        Me.UpdateStyles()
    End Sub
    Private Sub InitializeComponent()
        components = New System.ComponentModel.Container()
    End Sub
    Protected Overrides Sub OnPaint(ByVal pe As _
      System.Windows.Forms.PaintEventArgs)
        MyBase.OnPaint(pe)
        Dim myPen As New Pen(licol, libreit)
        If lirich = Richtung.Horizontal Then
            pe.Graphics.DrawLine(myPen, 0, Me.Height \ 2, Me.Width, Me.Height \ _
              2)
        Else
            pe.Graphics.DrawLine(myPen, Me.Width \ 2, 0, Me.Width \ 2, _
              Me.Height)
        End If
        myPen.Dispose()
    End Sub
End Class