Private Sub Test()
 
        Dim XMLDoc As New XmlDocument
 
        If writeNew Then 'Neue Documente erstellen
            CreateDoc(XMLDoc)
            AddDocument(XMLDoc, "0001", Now, "image1.gif", "1234567890")
        Else 'wenn's noch unter identischem Document ist
            XMLDoc.Load("C:\doc1.xml")
            AddDocument(XMLDoc, "0002", Now, "image2.gif", "2345678901")
        End If
        XMLDoc.Save("C:\doc1.xml")
 
    End Sub
 
    Private Sub CreateDoc(ByVal XMLDoc As XmlDocument)
        Dim dec As XmlNode = XMLDoc.CreateXmlDeclaration("1.0", String.Empty, _
          "yes")
        Dim root As XmlElement = XMLDoc.CreateElement("Index")
        root.SetAttributeNode("ID", String.Empty).Value = "TestFilm"
        XMLDoc.InsertAfter(dec, XMLDoc.DocumentElement)
        XMLDoc.InsertAfter(root, dec)
    End Sub
 
    Private Sub AddDocument(ByVal XMLDoc As XmlDocument, ByVal nr As String, _
      ByVal dt As Date, ByVal image As String, ByVal barCode As String)
        Dim doc As XmlElement
        doc = XMLDoc.CreateElement("Document")
        doc.SetAttributeNode("NR", String.Empty).Value = nr
        doc.SetAttributeNode("Date", String.Empty).Value = dt.ToString( _
          "yyyyMMdd HH:mm:ss")
        AddTextElement(XMLDoc, doc, "Image", image)
        AddTextElement(XMLDoc, doc, "BarCode", barCode)
        Dim elem As XmlElement = XMLDoc.DocumentElement
        elem.AppendChild(doc)
    End Sub
 
    Private Sub AddTextElement(ByVal XMLDoc As XmlDocument, ByVal doc As _
      XmlElement, ByVal name As String, ByVal text As String)
        Dim elem As XmlElement
        elem = XMLDoc.CreateElement(name)
        elem.InnerText = text
        doc.AppendChild(elem)
    End Sub

________
Alle Angaben ohne Gewähr. Keine Haftung für Vorschläge, Tipps oder sonstige Hilfe, falls es schiefgeht, nur Zeit verschwendet oder man sonst nicht zufrieden ist