Imports System.Drawing
Imports System.ComponentModel
Imports System.Windows.Forms.Design
 
''' <summary>
''' ToolStripItem CheckBox
''' </summary>
<ToolStripItemDesignerAvailabilityAttribute( _
  ToolStripItemDesignerAvailability.ToolStrip _
Or ToolStripItemDesignerAvailability.StatusStrip)> _
Public Class ToolStripCheckBox
   Inherits ToolStripControlHost
 
   Public Event CheckedChanged As EventHandler
 
   Public Sub New()
      MyBase.New(New CheckBox())
   End Sub
 
   Public ReadOnly Property CheckBox() As CheckBox
      Get
         Return CType(Control, CheckBox)
      End Get
   End Property
 
   Public Property Checked() As Boolean
      Get
         Return CheckBox.Checked
      End Get
      Set(ByVal value As Boolean)
         CheckBox.Checked = value
      End Set
   End Property
 
   Public Property CheckState() As CheckState
      Get
         Return CheckBox.CheckState
      End Get
      Set(ByVal value As CheckState)
         CheckBox.CheckState = value
      End Set
   End Property
 
   Public Property CheckAlign() As ContentAlignment
      Get
         Return CheckBox.CheckAlign
      End Get
      Set(ByVal value As ContentAlignment)
         CheckBox.CheckAlign = value
      End Set
   End Property
 
   Public Property ThreeState() As Boolean
      Get
         Return CheckBox.ThreeState
      End Get
      Set(ByVal value As Boolean)
         CheckBox.ThreeState = value
      End Set
   End Property
 
   Protected Overrides Sub OnSubscribeControlEvents(ByVal control As Control)
      MyBase.OnSubscribeControlEvents(control)
      Dim chkControl As CheckBox = CType(control, CheckBox)
      chkControl.BackColor = Color.Transparent
      AddHandler chkControl.CheckedChanged, AddressOf CheckBox_CheckedChanged
   End Sub
 
   Protected Overrides Sub OnUnsubscribeControlEvents(ByVal control As Control)
      MyBase.OnUnsubscribeControlEvents(control)
      Dim chkControl As CheckBox = CType(control, CheckBox)
      RemoveHandler chkControl.CheckedChanged, AddressOf CheckBox_CheckedChanged
   End Sub
 
   Private Sub CheckBox_CheckedChanged(ByVal sender As Object, ByVal e As _
     EventArgs)
      RaiseEvent CheckedChanged(Me, e)
   End Sub
End Class

Gru?
---------------------------------------------------
Snoopy sagt - vb@rchiv find ich gut...
Schon gesehen? OSMMapViewer V2 Control