Imports Microsoft.VisualBasic
Imports System.IO
Imports System.Text
Imports System.Xml
 
Public Class XMLCounter
 
 
   ''' <summary>
   ''' Pfad zum XML - Dokument
   ''' </summary>
   ''' <value></value>
   ''' <returns></returns>
   ''' <remarks></remarks>
   Public ReadOnly Property XmlDatei() As String
      Get
         Return System.Web.HttpContext.Current.Server.MapPath( _
           "~/app_data/counter.xml")
      End Get
   End Property
 
   Public Function ReadCounter() As Hashtable
      Dim locobjDoc As New XmlDocument
      Dim locobjUrlElement As XmlElement
      Dim locobjList As XmlNodeList
      Dim locobjHashTable As New Hashtable
 
      'XML-Dokument laden
      locobjDoc.Load(Me.XmlDatei)
 
      'Elemente auflisten
      locobjList = locobjDoc.SelectNodes("*//URL")
 
      For Each locobjUrlElement In locobjList
         locobjHashTable.Add(locobjUrlElement.Attributes("Name").Value, _
           locobjUrlElement.SelectSingleNode("Count").FirstChild.Value)
      Next
 
      Return locobjHashTable
 
   End Function
 
   Public Function GetCount(ByVal strCounterName As String) As Long
      Dim locobjDoc As New XmlDocument
      Dim locobjElement As XmlElement
 
      'XML-Dokument laden
      locobjDoc.Load(Me.XmlDatei)
 
      'einzelnes Element auswählen
      locobjElement = locobjDoc.SelectSingleNode("*//URL[@Name='" & _
        strCounterName & "']/Count")
      If locobjElement IsNot Nothing Then
         Return locobjElement.FirstChild.Value
      Else
         Return 0&
      End If
   End Function
 
   Public Function IncreaseCounter(ByVal strCounterName As String) As Long
      Dim locobjDoc As New XmlDocument
      Dim locobjElement As XmlElement
      Dim loclngValue As Long
 
      'XML-Dokument laden
      locobjDoc.Load(Me.XmlDatei)
 
      'einzelnes Element auswählen
      locobjElement = locobjDoc.SelectSingleNode("*//URL[@Name='" & _
        strCounterName & "']/Count")
      If locobjElement IsNot Nothing Then
         'Counter erhöhen
         loclngValue = locobjElement.FirstChild.Value + 1&
         locobjElement.FirstChild.Value = loclngValue
         locobjDoc.Save(Me.XmlDatei)
      Else
         NewCounter(strCounterName, 1&)
         loclngValue = 1&
      End If
      Return loclngValue
 
   End Function
 
   Public Sub NewCounter(ByVal strCounterName As String, ByVal lngStartValue As _
     Long)
      Dim locobjDoc As New XmlDocument
      Dim locobjElement As XmlElement
      Dim locobjNewElement As XmlElement
      Dim locobjAttribute As XmlAttribute
 
      'XML-Dokument laden
      locobjDoc.Load(Me.XmlDatei)
 
      'Startelement suchen
      locobjElement = locobjDoc.SelectSingleNode("Counter")
 
      'Neues Element
      locobjNewElement = locobjDoc.CreateNode(XmlNodeType.Element, "URL", "")
      locobjElement.AppendChild(locobjNewElement)
 
      'neues Attribut
      locobjAttribute = locobjDoc.CreateAttribute("Name")
      locobjAttribute.Value = strCounterName
      locobjNewElement.SetAttributeNode(locobjAttribute)
 
      'Elternelement wechseln
      locobjElement = locobjNewElement
 
      'Neues Element für den Counterwert
      locobjNewElement = locobjDoc.CreateNode(XmlNodeType.Element, "Count", "")
      locobjNewElement.InnerText = lngStartValue
      locobjElement.AppendChild(locobjNewElement)
 
      'Neues Element für das Erstellungsdatum
      locobjNewElement = locobjDoc.CreateNode(XmlNodeType.Element, "Created", _
        "")
      locobjNewElement.InnerText = DateTime.Now
      locobjElement.AppendChild(locobjNewElement)
 
      'Dokument speichern
      locobjDoc.Save(Me.XmlDatei)
 
   End Sub
End Class