-----------------------------------
Betriebssystem: Schrott (Vista)
Entwicklungsumgebung: VS 2008

<System.Serializable()> _
Public Class MyListViewSources
   Private pItems As ListViewItem()
 
   Public Sub New(ByVal Items As ListViewItem())
      pItems = Items
   End Sub
 
   Public Property Items() As ListViewItem()
      Get
         Return Me.pItems
      End Get
      Set(ByVal value As ListViewItem())
         Me.pItems = value
      End Set
   End Property
 
   Public Sub Save()
      Dim fs As New IO.FileStream(Application.UserAppDataPath & "\lvdata.dat", _
        IO.FileMode.Create)
      Dim formatter As New _
      System.Runtime.Serialization.Formatters.Binary.BinaryFormatter
 
      Try
         formatter.Serialize(fs, Me)
      Catch ex As Exception
         MsgBox(ex.Message)
      Finally
         fs.Close()
      End Try
   End Sub
 
   Public Shared Function Load() As MyListViewSources
      Dim fs As New IO.FileStream(Application.UserAppDataPath & "\lvdata.dat", _
        IO.FileMode.Open)
      Dim formatter As New _
      System.Runtime.Serialization.Formatters.Binary.BinaryFormatter
 
      Try
         Return DirectCast(formatter.Deserialize(fs), MyListViewSources)
      Catch ex As Exception
         MsgBox(ex.Message)
         Return Nothing
      Finally
         fs.Close()
      End Try
   End Function
End Class

Public Class Form2
   Private lvSources As MyListViewSources
 
   ' Speichern
   Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As _
     System.EventArgs) Handles Button1.Click
      ' Array von ListViewItem erstellen
      Dim arr(ListView1.Items.Count - 1) As ListViewItem
      ' Items aus dem ListView in das Array kopieren
      ListView1.Items.CopyTo(arr, 0)
 
      ' Neue Instanz erstellen und Array übergeben
      lvSources = New MyListViewSources(arr)
      ' Speichern
      lvSources.Save()
   End Sub
 
   ' Laden
   Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As _
     System.EventArgs) Handles Button2.Click
      ' Laden
      lvSources = MyListViewSources.Load()
 
      ' Jedes Item in das ListView hinzufügen, ggf. ListView1.Items.Clear() 
      ' aufrufen
      For Each item As ListViewItem In lvSources.Items
         ListView1.Items.Add(item)
      Next
   End Sub
End Class

-----------------------------------
Betriebssystem: Schrott (Vista)
Entwicklungsumgebung: VS 2008