Imports System.Drawing.Imaging
Public Class Form1
    Dim bmlist As New List(Of Bitmap)
    Dim WithEvents t As New Timer, Pb As New PictureBox
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As _
      System.EventArgs) Handles MyBase.Load
        bmlist.Add(New Bitmap(SystemIcons.Warning.ToBitmap))
        bmlist.Add(New Bitmap(SystemIcons.Error.ToBitmap))
        bmlist.Add(New Bitmap(SystemIcons.Information.ToBitmap))
        bmlist.Add(New Bitmap(SystemIcons.Shield.ToBitmap))
        bmlist.Add(New Bitmap(SystemIcons.Question.ToBitmap))
        bmlist.Add(bmlist(0))
        Pb.SetBounds(10, 10, 32, 32)
        Me.Controls.Add(Pb)
        t.Start()
    End Sub
 
    Private Sub t_Tick(ByVal sender As Object, ByVal e As System.EventArgs) _
      Handles t.Tick
        Pb.Invalidate()
    End Sub
 
    Private Sub Pb_Paint1(ByVal sender As Object, ByVal e As _
      System.Windows.Forms.PaintEventArgs) Handles Pb.Paint
        Static nr As Int32 = bmlist.Count - 2
        Static alpha As Single = 1.0
        alpha -= 0.02
        If alpha < 0.02 Then
            nr = IIf(nr < bmlist.Count - 2, nr + 1, 0)
            alpha = 1.0
        End If
        Dim rec As New Rectangle(0, 0, Pb.Width, Pb.Height)
        Dim cmatrix As New ColorMatrix
        Dim imgattr As New ImageAttributes()
        cmatrix.Matrix33 = alpha
        imgattr.SetColorMatrix(cmatrix)
        e.Graphics.DrawImage(bmlist(nr), rec, 0, 0, Pb.Width, Pb.Height, _
          GraphicsUnit.Pixel, imgattr)
        cmatrix.Matrix33 = 1.0 - alpha
        imgattr.SetColorMatrix(cmatrix)
        e.Graphics.DrawImage(bmlist(nr + 1), rec, 0, 0, Pb.Width, Pb.Height, _
          GraphicsUnit.Pixel, imgattr)
    End Sub
End Class