Imports System.Drawing.Drawing2D
Imports System.ComponentModel
 
Public Class RainbowLabel
    Inherits UserControl
    Private _Interval As Integer = 100
    Private _Text = "RegenbogenFarben"
    Private _Textalign As StringAlignment
    Private _Ani As Boolean
    Public Property Interval() As Integer
        Get
            Return _Interval
        End Get
        Set(ByVal value As Integer)
            _Interval = value
            t.Interval = _Interval
        End Set
    End Property
    Public Property Animation() As Boolean
        Get
            Return _Ani
        End Get
        Set(ByVal value As Boolean)
            _Ani = value
            t.Enabled = value
        End Set
    End Property
    <BrowsableAttribute(True)> _
    Public Overrides Property Text() As String
        Get
            Return _Text
        End Get
        Set(ByVal value As String)
            _Text = value
        End Set
    End Property
    Public Property Textalign() As StringAlignment
        Get
            Return _Textalign
        End Get
        Set(ByVal value As StringAlignment)
            _Textalign = value
        End Set
    End Property
    Private cList As New List(Of Color)
    WithEvents t As New Timer
 
    Private Sub RainbowLabel_Load(ByVal sender As Object, ByVal e As _
      System.EventArgs) Handles Me.Load
        Dim cb As Color() = {Color.Red, _
                    Color.Orange, Color.Yellow, Color.Green, Color.LightBlue, _
                    Color.Indigo, Color.Violet}
        cList.AddRange(cb)
        t.Interval = _Interval
        t.Enabled = _Ani
        Me.Size = TextRenderer.MeasureText(Me.Text, Me.Font, Me.Size, _
          TextFormatFlags.HorizontalCenter)
        Me.Height += Me.Font.Height / 2
    End Sub
    Private color_blend As New ColorBlend
    Private Sub RainbowLabel_Paint(ByVal sender As Object, ByVal e As _
      System.Windows.Forms.PaintEventArgs) Handles Me.Paint
        Using br As New LinearGradientBrush(New Point(0, 0), New  _
               Point(Me.DisplayRectangle.Width, Me.Height / 2), Color.Red, _
               Color.Violet)
            color_blend.Colors = cList.ToArray
            color_blend.Positions = New Single() {0, 0.16, 0.33, 0.47, 0.66, _
              0.82, 1}
            br.InterpolationColors = color_blend
            Dim sf As New StringFormat
            sf.Alignment = _Textalign
            e.Graphics.DrawString(_Text, Me.Font, br, Me.ClientRectangle, sf)
        End Using
    End Sub
 
    Private Sub t_Tick(ByVal sender As Object, ByVal e As System.EventArgs) _
      Handles t.Tick
        Dim lc As Color = cList.Item(6)
        cList.RemoveAt(6)
        cList.Insert(0, lc)
        Me.Refresh()
    End Sub
End Class

Wenn alle Stricke rei?en, dann h?ng ich mich auf. ~ Karl Kraus