Imports System.Runtime.InteropServices
 
Public Class Form1
    Inherits Form
 
#Region "Win32 API Stuff"
 
    ' Define the Win32 API methods we are going to use
    <DllImport("user32.dll")> _
    Private Shared Function GetSystemMenu(ByVal hWnd As IntPtr, ByVal bRevert _
    As Boolean) As IntPtr
    End Function
 
    <DllImport("user32.dll")> _
    Private Shared Function InsertMenu(ByVal hMenu As IntPtr, ByVal wPosition _
    As Int32, ByVal wFlags As Int32, ByVal wIDNewItem As Int32, ByVal lpNewItem _
    As String) As Boolean
    End Function
 
    ' Define our Constants we will use
    Public Const WM_SYSCOMMAND As Int32 = &H112
    Public Const MF_SEPARATOR As Int32 = &H800
    Public Const MF_BYPOSITION As Int32 = &H400
    Public Const MF_STRING As Int32 = &H0
 
#End Region
 
    ' The constants we'll use to identify our custom system menu items
    Public Const _SettingsSysMenuID As Int32 = 1000
    Public Const _AboutSysMenuID As Int32 = 1001
 
    Private Sub Form1_Load(ByVal sender As Object, ByVal e As EventArgs) _
      Handles MyBase.Load
 
        ' Get the Handle for the Forms System Menu
        Dim systemMenuHandle As IntPtr = GetSystemMenu(Me.Handle, False)
 
        ' Create our new System Menu items just before the Close menu item
        InsertMenu(systemMenuHandle, 5, MF_BYPOSITION Or MF_SEPARATOR, 0, _
          String.Empty)
        ' <-- Add a menu seperator
        InsertMenu(systemMenuHandle, 6, MF_BYPOSITION, _SettingsSysMenuID, _
          "Settings...")
        InsertMenu(systemMenuHandle, 7, MF_BYPOSITION, _AboutSysMenuID, _
        "About...")
 
    End Sub
 
    Protected Overrides Sub WndProc(ByRef m As Message)
 
        ' Check if a System Command has been executed
        If m.Msg = WM_SYSCOMMAND Then
            ' Execute the appropriate code for the System Menu item that was 
            ' clicked
            Select Case m.WParam.ToInt32()
                Case _SettingsSysMenuID
                    MessageBox.Show("""Settings"" was clicked")
                    Exit Select
                Case _AboutSysMenuID
                    MessageBox.Show("""About"" was clicked")
                    Exit Select
            End Select
        End If
 
        MyBase.WndProc(m)
 
    End Sub
 
End Class

________
Alle Angaben ohne Gewähr. Keine Haftung für Vorschläge, Tipps oder sonstige Hilfe, falls es schiefgeht, nur Zeit verschwendet oder man sonst nicht zufrieden ist