Private Sub DateienAuflisten(ByVal ordner As String, _
                             ByVal speichernAls As String, _
                             Optional ByVal dateiEndung As String = "*.*", _
                             Optional ByVal suchOption As  _
                             SearchOption = SearchOption.AllDirectories)
        Try
            ' Prüfen, ob der Suchpfad angegeben ist
            If String.IsNullOrEmpty(ordner) Then _
                Throw New Exception("Ordnername darf nicht leer sein.")
 
            ' Prüfen, ob der Pfad zum Speichern der Liste angegeben ist
            If String.IsNullOrEmpty(speichernAls) Then _
                Throw New Exception("Pfad zum Abspeichern darf nicht leer" & _
                "sein.")
 
            ' StribgBuilder zum temporären Speichern der Dateiliste
            ' Alternativ kann man auch List(Of T) nehmen.
            Dim sb As New System.Text.StringBuilder
 
            ' Instanz der DirectoryInfo-Klasse definieren
            ' Alternativ: My.Computer.FileSystem.GetFiles 
            Dim dInfo As New IO.DirectoryInfo(ordner)
 
            ' Name des Ordners definieren
            Dim ordnerName As String = dInfo.Name
 
            ' Pfad der Dateien ab Ordnername
            Dim dateiSubPath As String = String.Empty
            For Each fInfo As IO.FileInfo In dInfo.GetFiles(dateiEndung, _
              suchOption)
                ' Dateipfad trennen, d.h. Pfad bis zum Ordnername entfernen
                dateiSubPath = fInfo.FullName.Replace(dInfo.FullName, _
                  String.Empty)
 
                ' Ordnername und 'Restpfad' der Datei zusammenfügen 
                ' und die Liste aufnehmen
                sb.AppendLine(ordnerName & dateiSubPath)
            Next
 
            Dim fInfoSpeichern As New FileInfo(speichernAls)
            ' Prüfen ob der Ordner zum Speichern vorhanden ist.
            ' Gegebenfalls erstellen.
            If Not fInfoSpeichern.Directory.Exists Then _
                    fInfoSpeichern.Directory.Create()
 
            ' Speichern der Liste
            IO.File.WriteAllText(fInfoSpeichern.FullName, _
                                 sb.ToString, _
                                 System.Text.Encoding.Default)
        Catch ex As Exception
            MsgBox(ex.Message, MsgBoxStyle.OkOnly)
        End Try
    End Sub

        Me.DateienAuflisten( _
          My.Computer.FileSystem.SpecialDirectories.MyDocuments & _
          "\Ordner1\File2", "C:\TestFile2.txt")