Public Class LVTabPage
   Inherits TabPage
 
   Private m_ListView As ListView
 
   Public ReadOnly Property ListView() As ListView
      Get
         Return m_ListView
      End Get
   End Property
 
   Protected Overrides Sub OnHandleCreated(ByVal e As System.EventArgs)
      m_ListView = New ListView
      With m_ListView
         .Dock = DockStyle.Fill
         .View = View.Details
         .FullRowSelect = True
         .GridLines = True
 
         ' Columns definieren
         .Columns.Add("Datei", 200, HorizontalAlignment.Left)
         .Columns.Add("Datum", 100, HorizontalAlignment.Left)
         .Columns.Add("Größe", 100, HorizontalAlignment.Right)
      End With
      Me.Controls.Add(m_ListView)
 
      MyBase.OnHandleCreated(e)
   End Sub
End Class

Public Class Form1
 
   Private Const sLetter As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 
   Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As _
     System.EventArgs) Handles MyBase.Load
 
      ' 26 TabPages vom Typ LVTabPage hinzufügen
      For i As Int16 = 0 To 25
         Dim tp As New LVTabPage
         tp.Text = sLetter(i)
         tp.Name = "TabPage_" & sLetter(i)
         Me.TabControl1.TabPages.Add(tp)
      Next
 
 
      ' Die LVTabPage TypeCasten, so dass man Zugriff darauf hat.
      Dim myTabPage As LVTabPage = CType(Me.TabControl1.TabPages("TabPage_A"), _
        LVTabPage)
 
      ' Ein paar Test-Items hinzufügen
      myTabPage.ListView.Items.Add("Datei 1")
      myTabPage.ListView.Items.Add("Datei 2")
      myTabPage.ListView.Items.Add("Datei 3")
   End Sub
 
 
   Private Sub TabControl1_Selected(ByVal sender As System.Object, ByVal e As _
     System.Windows.Forms.TabControlEventArgs) Handles TabControl1.Selected
      Dim myTabPage As LVTabPage = CType(e.TabPage, LVTabPage)
      MsgBox("Klick auf " & myTabPage.Name)
   End Sub
End Class

Gru?
---------------------------------------------------
Snoopy sagt - vb@rchiv find ich gut...
Schon gesehen? OSMMapViewer V2 Control