Private Function TrimToUpper(ByVal s As String) As String
   'Hilfsfunktion: 
   'Konvertiert eine Stringliste in Großschreibung
   Return Trim(s.ToUpper)
End Function
 
''' <summary> Jüngere Dateien (letzte Änderung) kopieren</summary>
''' <param name="sourcedir">Quellverzeichnis</param>
''' <param name="destdir">Zielverzeichnis</param>
''' <param name="RemoveReadOnly">Darf ReadOnly-Attribut im Ziel entfernt 
' werden?</param>
''' <param name="ErrorMessage">Protokoll der Fehlermeldungen</param>
''' <returns>Alles OK?</returns>
Public Function CopyFilesIfNewer(ByVal sourcedir As String, _
                                 ByVal destdir As String, _
                Optional ByVal RemoveReadOnly As Boolean = False, _
                Optional ByRef ErrorMessage As String = "") As Boolean
 
    ErrorMessage = "Verzeichnis nicht vorhanden"
    If Not IO.Directory.Exists(sourcedir) Then Return False
    If Not IO.Directory.Exists(destdir) Then Return False
 
    'Rückgabe initialisieren
    Dim retcode As Boolean = True
    ErrorMessage = String.Empty
 
    Try
       'Liste der Datei-Infos im Quellverzeichnis ermitteln
       Dim source As List(Of IO.FileInfo) = _
       New IO.DirectoryInfo(sourcedir).EnumerateFiles.ToList
 
       'Liste der Dateinamen im Zielverzeichnis ermitteln
       Dim destination As List(Of String) = _
       IO.Directory.GetFiles(destdir).ToList. _
       ConvertAll(New Converter(Of String, String)(AddressOf TrimToUpper))
 
       For Each src As IO.FileInfo In source
          'voller Pfad der zu kopierenden Datei im Zielverzeichnis
          Dim dest As String = _
          IO.Path.Combine(destdir, src.Name).Trim.ToUpper
 
          Try
             If destination.Contains(dest) Then
                'Dateiname im Zielordner bereits vorhanden ....
                Dim destinfo As New IO.FileInfo(dest)
                Dim desttime As Date = destinfo.LastWriteTime
                If desttime < src.LastWriteTime Then
                   'die bereits vorhandene Datei im Zielordner ist älter 
                   Dim ro As Boolean = destinfo.IsReadOnly
                   If RemoveReadOnly Then
                      'Schreibschutz im Ziel ggf. entfernen
                      destinfo.IsReadOnly = False
                   End If
                   'Datei im Zielordner löschen
                   IO.File.Delete(dest)
                   'Datei kopieren
                   IO.File.Copy(src.FullName, dest)
                   destinfo = New IO.FileInfo(dest)
                   'Schreibschutz-Einstellung im Ziel wieder herstellen
                   destinfo.IsReadOnly = ro
                End If
             Else
                'Dateiname im Zielordner nicht vorhanden
                IO.File.Copy(src.FullName, dest)
             End If
          Catch ex As Exception
             'Kopieren einer Datei erzeugt Ausnahme: Protokoll
             ErrorMessage &= (ex.Message & Microsoft.VisualBasic.vbNewLine)
             retcode = False
          End Try
       Next src 'Schleife über Quell-Dateien
 
       Return retcode
    Catch ex As Exception       
       ErrorMessage &= ("Abbruch: " & ex.Message & _
         Microsoft.VisualBasic.vbNewLine)
       Return False
    End Try
End Function