Imports System.Drawing.Drawing2D
Public Class Form1
    Private WithEvents Pb As New PictureBox With {.Dock = DockStyle.Fill, _
      .Parent = Me}
    Private bm As New Bitmap(300, 300) ' als Bildersatz X
    Private angle As Int32 = 45
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) _
      Handles MyBase.Load
        Me.ClientSize = New Size(424, 424)
    End Sub
 
    Private Sub Form1_KeyDown(sender As Object, e As _
      System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
        If e.KeyCode = Keys.Left AndAlso angle > 0 Then angle -= 1
        If e.KeyCode = Keys.Right AndAlso angle < 360 Then angle += 1
        Pb.Invalidate()
    End Sub
 
    Private Sub Pb_Paint(sender As Object, e As _
      System.Windows.Forms.PaintEventArgs) Handles Pb.Paint
        Dim r As New Rectangle(0, 0, bm.Width, bm.Height)
        Using m As New Matrix, gp As New GraphicsPath
            gp.AddRectangle(r)
            m.RotateAt(angle, New Point(r.Width >> 1, r.Height >> 1))
            gp.Transform(m)
            Using nbm = New Bitmap(CInt(gp.GetBounds.Width), CInt( _
              gp.GetBounds.Height)), g = Graphics.FromImage(nbm)
                g.SmoothingMode = SmoothingMode.AntiAlias
                g.Clear(Color.Black)
                m.Reset()
                m.RotateAt(angle, New Point(nbm.Width >> 1, nbm.Height >> 1))
                g.Transform = m
                g.FillRectangle(Brushes.Yellow, New Rectangle((nbm.Width - _
                  r.Width) >> 1, (nbm.Height - r.Height) >> 1, _
                  r.Width, r.Height)) 'X
                e.Graphics.DrawImage(nbm, 0, 0)
                Me.Text = nbm.Size.ToString & ", angle: " & angle.ToString
            End Using
        End Using
    End Sub
End Class