Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As _
      System.EventArgs) Handles Button2.Click
        If FolderBrowserDialog1.ShowDialog = Windows.Forms.DialogResult.OK Then
            With ImageList1
                ' Liste leeren
                .Images.Clear()
                ' Größe der anzuzeigenden Bilder festlegen
                .ImageSize = New Size(16, 16)
            End With
            Try
                Dim ImageIndex As Integer = 0
                Dim ListViewItem As ListViewItem = Nothing
                With ListView1
                    .BeginUpdate()
                    .SmallImageList = ImageList1
                    .Items.Clear()
                    .Columns.Clear()
                    .Columns.Add("Dateiname")
                    .View = View.Details
                    ' Alle Dateien im angegebene Pfad suchen *.* für alle 
                    ' Dateien, 
                    '*.txt für Textdateien, *.mpg für MPEG Dateien  usw.
                    ' Hier wird nach allen Dateiformaten gesucht
                    For Each item As String In System.IO.Directory.GetFiles( _
                            FolderBrowserDialog1.SelectedPath, "*.*")
                        ' aktuelles Bild in die ImageList laden
                        Dim ico As System.Drawing.Icon = _
                            System.Drawing.Icon.ExtractAssociatedIcon(item)
                        ImageList1.Images.Add(ico.ToBitmap)
                        ' Dateiinformationen abrufen
                        Dim fi As New System.IO.FileInfo(item)
                        ' Neues ListViewItem mit Dateinamen erstellen
                        ListViewItem = New ListViewItem(fi.Name, ImageIndex)
                        ' ListViewItem in ListView1 einfügen
                        .Items.Add(ListViewItem)
                        ' Bildindex hochzählen
                        ImageIndex += 1
                    Next
                    .AutoResizeColumn(0, _
                      ColumnHeaderAutoResizeStyle.ColumnContent)
                    .EndUpdate()
                End With
            Catch ex As Exception
                MsgBox(ex.Message)
            End Try
        End If
    End Sub