Visual Basic Quellcode 
 
    Dim tvwAusgewählt As String
    Dim tvwSchlüssel As Integer
 
    ''' <summary>
    ''' Füllt das TreeView mit den Knoten des XML-Documents
    ''' </summary>
    ''' <remarks>
    ''' Numeriert die Elemente über ihre Name-Eigenschaft. 
    ''' Ruft zum weiteren Einlesen ebeneLesen auf
    ''' </remarks>
    Sub tvwFüllen()
        txtAusgabe.Text = ""
        tvw.BeginUpdate()
        tvw.Nodes.Clear()
 
        Dim xKnotenListe As XmlNodeList = xmlDok.SelectNodes("*")
        Dim tKnoten As TreeNode = tvw.Nodes.Add("")
 
        tvwSchlüssel = 0
        tKnoten.Name = tvwSchlüssel.ToString("00")
        For Each xn As XmlNode In xKnotenListe
            ebeneLesen(xn, tKnoten)
        Next
 
        tvw.EndUpdate()
        tvw.Select()
    End Sub
 
    ''' <summary>
    ''' Rekursives Einlesen von xmlNode zu TreeNode
    ''' </summary>
    ''' <param name="xmlKnoten">
    ''' Knoten des Xml-Dokuments
    ''' </param>
    ''' <param name="treeKnoten">
    ''' Enthält als Tag wahlweise die Eigenschaft
    ''' OuterXml, InnerXml, InnerText, Attributes oder
    ''' Name und Text des treeknoten.</param>
    ''' <remarks></remarks>
    Sub ebeneLesen(ByVal xmlKnoten As XmlNode, ByVal treeKnoten As TreeNode)
 
        tvwSchlüssel += 1
        treeKnoten.Text = xmlKnoten.Name
 
        Select Case True
            Case rbOuterXml.Checked
                treeKnoten.Tag = "OuterXml:" & vbCrLf & xmlKnoten.OuterXml
            Case rbInnerXml.Checked
                treeKnoten.Tag = "InnerXml: " & vbCrLf & xmlKnoten.InnerXml
            Case rbInnerText.Checked
                treeKnoten.Tag = "InnerText: " & vbCrLf & xmlKnoten.InnerText
            Case rbAttributes.Checked
                treeKnoten.Tag = "Attribute: " & vbCrLf
                treeKnoten.Tag &= "Name" & vbTab & vbTab & "InnerText" & vbCrLf
                For Each xmlAtt As XmlAttribute In xmlKnoten.Attributes
                    Dim s As String = xmlAtt.Name & vbTab
                    If s.Length < Strings.Len("Name" & vbTab & vbTab) Then
                        s &= vbTab
                    End If
                    treeKnoten.Tag &= s & xmlAtt.InnerText & vbCrLf
                Next
            Case rbTreeView.Checked
                treeKnoten.Tag = "Name:" & vbTab & vbTab & "Text" & vbCrLf _
                                & treeKnoten.Name & vbTab & vbTab & _
                                treeKnoten.Text
            Case Else
                treeKnoten.Tag = "InnerText: " & vbCrLf & xmlKnoten.InnerText
        End Select
 
        Dim tn As TreeNode
        Dim xn As XmlNode
        For Each xn In xmlKnoten.ChildNodes
            If xn.HasChildNodes Then
                tn = treeKnoten.Nodes.Add(tvwSchlüssel.ToString("00"), xn.Name)
                ebeneLesen(xn, tn)
            End If
        Next
    End Sub