Public Class ImageListEventArgs
    Inherits EventArgs
    Dim _ImageAddedStartIndex As Integer
 
    Public Sub New(ByVal Startindex As Integer)
        _ImageAddedStartIndex = Startindex
    End Sub
 
    ''' <summary>Index des ersten neu hinzugefügten Bildes</summary>
    Public ReadOnly Property ImageAddedStartIndex() As Integer
        Get
            Return _ImageAddedStartIndex
        End Get
    End Property
End Class
 
Public Class ImageList
    Inherits List(Of Image)
 
    Dim ofd As New OpenFileDialog With {
    .Title = "ImageList: Bilder hinzufügen", .Multiselect = True, _
     .Filter = "Bilder |*.bmp;*.jpg;*.gif;*.png|Alle Dateien|*.*", _
     .CheckFileExists = True}
 
    Dim InitialFolder As String = _
      My.Computer.FileSystem.SpecialDirectories.MyPictures
 
    Public Event ImagesAdded(ByVal sender As Object, ByVal e As _
      ImageListEventArgs)
 
    ''' <summary>Bilder per OpenFileDialog an die Liste anhängen</summary>
    ''' <returns>Anzahl der angehängten Bilder (ggf. 0)</returns>
    Public Function AddByFileDialog() As Integer
        With ofd
            If .ShowDialog = DialogResult.Cancel Then Return 0
            If .FileNames.Length < 1 Then Return 0
            Dim startindex As Integer = Me.Count
            For i As Integer = 0 To .FileNames.Length - 1
                Dim img As New Image With {.Height = 100, .Width = 100}
                img.Source = New BitmapImage(New Uri(ofd.FileNames(i)))
                Me.Add(img)
            Next i
            InitialFolder = IO.Path.GetDirectoryName(.FileNames(0))
            RaiseEvent ImagesAdded(Me, New ImageListEventArgs(startindex))
            Return .FileNames.Length
        End With
    End Function
End Class

Dim WithEvents myImages As New ImageList

Private Sub Button_Click(ByVal sender As System.Object, _
     ByVal e As System.Windows.RoutedEventArgs) Handles Button1.Click
 
     myImages.AddByFileDialog()
End Sub

Private Sub ImagesAdded(ByVal sender As Object, _
     ByVal e As ImageListEventArgs) Handles myImages.ImagesAdded
 
     For i As Integer = e.ImageAddedStartIndex To myImages.Count - 1
        WrapPanel1.Children.Add(myImages(i))
     Next i
End Sub