Imports System.Linq
 
Public Class frmSlideShow
 
    'Erforderliche Controls erstellen einrichten
    Dim WithEvents tim As New Timer With {.Enabled = True, .Interval = 4000}
    Dim pbox As New PictureBox With _
    {.Parent = Me, .Dock = DockStyle.Fill, .SizeMode = PictureBoxSizeMode.Zoom}
 
    'Liste für die Dateinamen der Bilder
    Dim piclist As New List(Of String)
 
    'Reaktion auf Tastendruck hier einbauen ....
    Private Sub form_KeyDown(ByVal sender As Object, _
                ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
 
        Dim taste As String = String.Empty
        If e.KeyCode = Keys.A Then taste = "A"
        If e.KeyCode = Keys.B Then taste = "B"
 
        If taste <> String.Empty Then
            MsgBox("Taste " & taste & " wurde gedrückt", _
            MsgBoxStyle.Information, "Slideshow")
        End If
 
    End Sub
 
    Private Sub frmSlideShow_Load(ByVal sender As System.Object, _
                             ByVal e As System.EventArgs) Handles MyBase.Load
 
        'Beim Programmstart -> Dateinamen ermitteln und listen
        With My.Computer.FileSystem
            piclist = .GetFiles(.SpecialDirectories.MyPictures).ToList
        End With
        'Formular wird über alle Tstendrücke informiert
        Me.KeyPreview = True
        'Slideshow startet sofort: Timer wird aktiv
        tim.Enabled = True
    End Sub
 
    Private Sub tim_Tick(ByVal sender As Object, ByVal e As System.EventArgs) _
      Handles tim.Tick
        'statische Variable für Index in Dateiliste
        Static index As Integer = -1
        index += 1
        If index => piclist.Count Then index = 0 'umlaufende Show
        'Bild laden 
        pbox.Image = New Bitmap(piclist(index))
        'Info anzeigen
        Me.Text = CStr(index) & ".   " & IO.Path.GetFileName(piclist(index))
    End Sub
End Class