Public Class frmPicBrowser 'Dieses Statement ist bereits vorhanden
 
   'Dialog und Picturebox incl. Eigenschaften erstellen
    Dim fbd As New FolderBrowserDialog With _
    {.Description = "Ordner mit Bilddateien wählen", .ShowNewFolderButton = _
    False}
    Dim pbox As New PictureBox With _
    {.Parent = Me, .Dock = DockStyle.Fill, .SizeMode = PictureBoxSizeMode.Zoom}
 
    'Erstellung der Verwaltungs-Variablen:
    '======================================
    'Array mit den unterstützten Bilddatei-Extensions incl. Wildcard für 
    ' Getfiles-Methode
    Dim picfileextensions() As String = _
    {"*.jpg", "*.jpeg", "*.png", "*gif", "*.tiff", "*.tif", "*.bmp"}
 
    'Liste der Dateinamen im gewählten Ordner
    Dim picfiles As New List(Of String)
 
    'Hier wird jeweils der aktuelle Bildindex abgelegt
    Dim picindex As Integer
 
    Private Sub frmPicBrowser_KeyDown(ByVal sender As Object, _
        ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
 
        'Verarbeitung der Steuerungstasten
 
        Dim stepp As Integer = 1
        If e.Modifiers = Keys.Control Then stepp = 10 'CTRL-Taste: höhere 
        ' Schrittweite
 
        Select Case e.KeyCode
            Case Is = Keys.F1
                Dim t As String = "Tastenfunktionen: " & vbCrLf & vbCrLf & _
                    "F-Taste: Ordnerauswahl" & vbCrLf & _
                    "PageUp/PageDown: Navigation durch Bilddateien" & vbCrLf & _
                    "CTRL erhöht die Schrittweite der Navigation" & vbCrLf & _
                    "Home/End: Sprung zur ersten/letzten Datei in der Liste"
                MsgBox(t, MsgBoxStyle.Information, "PicBrowser")
            Case Is = Keys.F
                'Orderauswahl-Dialog (ggf. Abbruch durch User)
                If fbd.ShowDialog = DialogResult.Cancel Then Exit Sub
 
                Me.Text = "Bilddateien werden ermittelt ....."
                With My.Computer.FileSystem
                    picfiles = .GetFiles(fbd.SelectedPath, _
                                FileIO.SearchOption.SearchTopLevelOnly, _
                                picfileextensions).ToList
                End With
                If picfiles.Count < 1 Then
                    MsgBox("Ordner enthält keine GDI+unterstützten" & _
                      "Datei-Formate")
                    picindex = -1
                Else
                    picindex = 0
                End If
            Case Is = Keys.PageDown                
                picindex = Math.Min(picfiles.Count - 1, picindex + stepp)
            Case Is = Keys.PageUp
                picindex = Math.Max(0, picindex - stepp)                
            Case Is = Keys.Home
                picindex = 0
            Case Is = Keys.End
                picindex = picfiles.Count - 1
        End Select
 
        'Bild aus der Datei am aktuellen Listenindex laden (falls möglich)
        LoadPic()
    End Sub
 
    Private Sub LoadPic()
        If picindex >= 0 And picindex < picfiles.Count Then
            'Bild laden und Dateiname anzeigen
            pbox.LoadAsync(picfiles(picindex))
            Me.Text = "[" & CStr(picindex + 1) & " von  " & _
                CStr(picfiles.Count) & "] " & _
                IO.Path.GetFileName(picfiles(picindex))
        Else
            pbox.Image = pbox.ErrorImage
            Me.Text = "Keine Bilddatei vorhanden"
        End If
    End Sub
 
End Class 'Dieses Statement ist bereits vorhanden