Public Class frmCurve
 
    Dim WithEvents tim As New Timer With _
        {.Interval = 100, .Enabled = True}
 
    Dim pointstodraw As New System.Collections.Generic.List(Of Point)
 
    Private Sub frmCurve_Load(ByVal sender As System.Object, _
        ByVal e As System.EventArgs) Handles MyBase.Load
 
        FormBorderStyle = Windows.Forms.FormBorderStyle.FixedSingle
        Size = New Size(400, 400)
        BackColor = Color.White
        DoubleBuffered = True
 
        pointstodraw.Add(New Point(0, 0))
    End Sub
 
    Private Sub frmCurve_Paint(ByVal sender As Object, _
        ByVal e As System.Windows.Forms.PaintEventArgs) Handles Me.Paint
 
        Using br As New SolidBrush(Color.Black), _
                br_line As New SolidBrush(Color.Red), _
                pn As New Drawing.Pen(br, 2), _
                pn_line As New Drawing.Pen(br_line, 2)
            With e.Graphics
                .DrawLine(pn, 5, (Me.Height - 10) \ 2, Me.Width - 10, ( _
                  Me.Height - 10) \ 2)
                .DrawLine(pn, Me.Width \ 2, 5, Me.Width \ 2, Me.Height - 25)
                For i As Integer = 0 To pointstodraw.Count - 2
                    .DrawLine(pn_line, pointstodraw(i), pointstodraw(i + 1))
                Next
                .DrawString("x-achse, links", New Font("Arial", 12), br, 5, ( _
                  Me.Height - 50) \ 2)
            End With
        End Using
    End Sub
 
    Private Sub tim_Tick(ByVal sender As Object, ByVal e As System.EventArgs) _
      Handles tim.Tick
        Static ang As Double = 0
        ang += 0.1
        Dim y As Integer = CInt(Math.Sin(ang) * (Me.Height - 40) / 2) + ( _
          Me.Height - 40) \ 2
        Dim x As Integer = pointstodraw(pointstodraw.Count - 1).X + 3
        If x > Me.Width - 20 Then
            For i As Integer = pointstodraw.Count - 1 To 1 Step -1
                pointstodraw(i) = New Point(pointstodraw(i - 1).X, pointstodraw( _
                  i).Y)
            Next i
            pointstodraw.RemoveAt(0)
        End If
        pointstodraw.Add(New Point(x, y))
        Invalidate()
    End Sub
End Class