Hier noch ein kleines Beispiel für
Treeview/Gridview-Kombination (Datensatz-Filter bei Datenbindung) ...
Public Class frmTreeGridDemo
'Erforderliche Controls erstellen
Dim spc As New SplitContainer With
{.Parent = Me, .Dock = DockStyle.Fill}
Dim WithEvents trv As New TreeView With _
{.Dock = DockStyle.Fill, .Parent = spc.Panel1}
Dim dgv As New DataGridView With _
{.Dock = DockStyle.Fill, .Parent = spc.Panel2}
'Datenquelle und Bindung
Dim dt As DataTable
Dim bs As New BindingSource
Private Sub frmTreeGridDemo_Load(sender As System.Object, _
e As System.EventArgs) Handles MyBase.Load
'Einige Testdaten besorgen
dt = getData()
'Datenbindung herstellen
bs.DataSource = dt
dgv.DataSource = bs
'Datensätze hierarchisch sortieren
bs.Sort = dt.Columns(0).ColumnName & ", " & _
dt.Columns(1).ColumnName & " ASC"
'Treeview mit den ersten Spalten füllen
FillTreeview(bs)
'Datagridview einrichten
With dgv
.AllowUserToAddRows = False : .AllowUserToDeleteRows = False
.Columns(0).Visible = False : .Columns(1).Visible = False
End With
End Sub
Private Function getData() As DataTable
'Beispieldaten erzeugen
Dim rndm As New Random, dt As New DataTable
For c As Integer = 0 To 3
dt.Columns.Add("SP_" & CStr(c), GetType(String))
Next c
For r As Integer = 0 To 100
dt.Rows.Add(New Object() _
{CStr(rndm.Next(1, 10)), CStr(rndm.Next(1, 3)), _
CStr(rndm.Next), CStr(rndm.Next)})
Next r
Return dt
End Function
Private Function FillTreeview(ByVal bs As BindingSource) As Boolean
'Die ersten beiden Spalten einer an eine Source
'gebundenen Table in ein Treeview eintragen
Try
For r As Integer = 0 To bs.Count - 1
Dim row As DataRow = CType(bs(r), DataRowView).Row
If Not IsDBNull(row(0)) And Not IsDBNull(row(1)) Then
Dim trv_key As String = CStr(row(0))
Dim trv_subkey As String = CStr(row(1))
If trv.Nodes.ContainsKey(trv_key) Then
If Not trv.Nodes(trv_key).Nodes.ContainsKey(trv_subkey) _
Then
trv.Nodes(trv_key).Nodes.Add(trv_subkey, trv_subkey)
End If
Else
trv.Nodes.Add(trv_key, trv_key)
trv.Nodes(trv_key).Nodes.Add(trv_subkey, trv_subkey)
End If
End If
Next r
Return True
Catch
Return False
End Try
End Function
Private Sub FilterByNode(nd As TreeNode)
'Source-Filterstring zu einem der Treeview-Subnodes erstellen
Dim dt As DataTable = CType(bs.DataSource, DataTable)
bs.Filter = dt.Columns(0).ColumnName & " = " & "'xxxxxxxx'"
If nd.Parent Is Nothing Then Exit Sub 'Subnode?
Dim col2_value As String = CStr(nd.Text)
Dim col1_value As String = CStr(nd.Parent.Text)
Dim filterstring As String = _
"[" & dt.Columns(0).ColumnName & "] = '" & col1_value & "' AND [" & _
dt.Columns(1).ColumnName & "] = '" & col2_value & "'"
bs.Filter = filterstring
End Sub
Private Sub trv_BeforeSelect(sender As Object, _
e As System.Windows.Forms.TreeViewCancelEventArgs) Handles _
trv.BeforeSelect
FilterByNode(e.Node)
End Sub
End Class |