Public Class cVector
 
    Private _data() As Double
    Private Const MaxVectorLength As Integer = 100
 
    Private Sub ArrayInit(ByVal data() As Double)
        If data Is Nothing OrElse data.Length < 1 Then
            Throw New ArgumentException("Keine Vektordaten verfügbar")
        End If
 
        If data.Length > MaxVectorLength Then
            Throw New ArgumentException("Ungeeignete Vektorlänge")
        End If
 
        'der Array-Inhalt wird kopiert
        _data = CType(data.Clone, Double())
    End Sub
 
    Public Sub New(ByVal data() As Double)
        ArrayInit(data)
    End Sub
 
    Public Sub New(ByVal vector As cVector)
        If vector Is Nothing Then
            Throw New ArgumentException("Kein Vektor verfügbar")
        End If
        ArrayInit(vector._data)
    End Sub
 
    Public Sub New(Optional ByVal Length As Integer = 1)
        If Length < 1 OrElse Length > MaxVectorLength Then
            Throw New ArgumentException("Ungeeignete Vektorlänge")
        End If
        Array.Resize(_data, Length)
    End Sub
 
    Public ReadOnly Property Length() As Integer
        Get
            Return _data.Length
        End Get
    End Property
 
    Default Public Property Element(ByVal index As Integer) As Double
        Get
            Return _data(index)
        End Get
        Set(value As Double)
            If Double.IsNaN(value) OrElse Double.IsInfinity(value) Then
                Throw New InvalidExpressionException _
                    ("IEEE-Sonderwert kann nicht zugewiesen werden")
            End If
 
            'Hier weitere Validierungen des entstehenden Vektors einbauen
            '............
 
            _data(index) = value
        End Set
    End Property
 
    Public Shared Operator +(ByVal a As cVector, b As cVector) As cVector
        If Not a.Length = b.Length Then
            Throw New ArgumentException("Ungleiche Vektorlänge")
        End If
 
        Dim c As New cVector(a.Length)
 
        For i As Integer = 0 To a.Length - 1
 
            'Die sichere Variante der Wertzuweisung
            'c(i) = a(i) + b(i)
 
            'Die schnelle Variante der Wertzuweisung
            c._data(i) = a._data(i) + b._data(i)
        Next i
 
        Return c
    End Operator
 
    Public Shared Operator -(ByVal a As cVector, b As cVector) As cVector
        If Not a.Length = b.Length Then
            Throw New ArgumentException("Ungleiche Vektorlänge")
        End If
 
        Dim c As New cVector(a)
        For i As Integer = 0 To a.Length - 1
            c._data(i) -= b._data(i)
        Next i
 
        Return c
    End Operator
End Class